×
INTELLIGENT WORK FORUMS
FOR COMPUTER PROFESSIONALS

Contact US

Log In

Come Join Us!

Are you a
Computer / IT professional?
Join Tek-Tips Forums!
  • Talk With Other Members
  • Be Notified Of Responses
    To Your Posts
  • Keyword Search
  • One-Click Access To Your
    Favorite Forums
  • Automated Signatures
    On Your Posts
  • Best Of All, It's Free!

*Tek-Tips's functionality depends on members receiving e-mail. By joining you are opting in to receive e-mail.

Posting Guidelines

Promoting, selling, recruiting, coursework and thesis posting is forbidden.

Students Click Here

Drawingboard III Tablet

Drawingboard III Tablet

Drawingboard III Tablet

(OP)
I recently purchased a Drawingboard III tablet and want to use it to digitize data (points) from a graph and put the coordinates  into a computer file.  I have done this previously with a SummaSketch III tablet using a program in QBASIC on an older computer, but cannot duplicate this with Drawingboard III and QBASIC with my IBM Aptiva 2139 computer.  I have AutoSketch software which can operate in the tracing mode with the new Drawingboard tablet, but cannot digitize graph data.  Can someone suggest software that could digitize data with the Drawingboaard III tablet or suggest an approach to writing a program in one of the standard computer languages such as C, Fortran, Basic, Pascal, etc?

RE: Drawingboard III Tablet

The world of CAD and CAD accessories is very large.
If you would post the Qbasic code you used to digitize SummaSketch III I will try to find it's specs (and Drawingboard III's specs) on the internet and perhaps come up with a programming solution for you.
If you are using AutoCAD 2000 it will be so much nicer, since it supports Visual Basic for Applications. From the time I installed CAD 2000 on my workstation I have made my co-workers realize that the possibilities are nearly limitless!



A plain black box

RE: Drawingboard III Tablet

Just to keep this discussion in one thread I am pasting the code you posted elsewhere:

DIG.BAS

1 'DIGITIZING PROGRAM FOR SUMMAGRAPHICS DIGITIZER
2 '
3 ' HIT SHIFT-F5 TO RUN
4 '
9 ' WRITTEN BY PAUL MURLEY, JULY 17, 1995
19 CLS
20 PRINT "THIS IS A PROGRAM FOR DIGITIZING GRAPHS WITH THE SUMMAGRAPHICS DIGITIZING TABLET"
21 PRINT "IT WILL CONVERT LINEAR, LINEAR-LOG, AND LOG-LOG GRAPHS (BASE 10)"
22 PRINT
23 PRINT "YOU MUST HAVE A DATA DISKETTE IN DRIVE A:"
24 PRINT
25 PRINT
28 ' THIS PROGRAM ASSUMES THAT THE DIGITIZER HAS BEEN
32 ' PRECONFIGURED WITH THE SUMMA SEND COMMAND TO RESPOND
36 ' USING THE COM PARAMETERS BELOW
38 OPEN "COM1:9600,E,7,2" FOR RANDOM AS #1
40 E$ = CHR$(27) ' THIS ASSIGNS <ESC> TO E$ (NEEDED FOR SUMMA COMMANDS)
45 WRITE #1, E$, "M1" 'TELLS DIGITIZER TO SEND SINGLE POINTS
50 PRINT "IS THE X AXIS LOGARITHMIC (Y/N)?"
60 INPUT IXLL$
70 PRINT "IS THE Y AXIS LOGARITHMIC (Y/N)?"
80 INPUT IYLL$
100 PRINT "DIGITIZE THE ORIGIN OF THE PLOT (PRESS ANY POINTER BUTTON)"
200 INPUT #1, I0, J0, F0, P0
201 BEEP
250 PRINT
300 PRINT "ENTER THE COORDINATES OF THIS POINT (X,Y)"
400 INPUT X0, Y0
410 IF IXLL$ = "Y" THEN X0 = LOG(X0) / LOG(10)
420 IF IYLL$ = "Y" THEN Y0 = LOG(Y0) / LOG(10)
450 CLS
500 PRINT "DIGITIZE A POINT ON THE X-AXIS"
510 INPUT #1, I1, J1, F1, P1
511 BEEP
525 PRINT
550 PRINT " ENTER THE COORDINATES OF THIS POINT (X,Y)"
560 INPUT X1, Y1
570 IF IXLL$ = "Y" THEN X1 = LOG(X1) / LOG(10)
580 IF IYLL$ = "Y" THEN Y1 = LOG(Y1) / LOG(10)
590 CLS
700 PRINT "DIGITIZE A POINT ON THE Y-AXIS"
800 INPUT #1, I2, J2, F2, P2
801 BEEP
850 PRINT
900 PRINT "ENTER THE COORDINATES OF THIS POINT (X,Y)"
1000 INPUT X2, Y2
1010 IF IXLL$ = "Y" THEN X2 = LOG(X2) / LOG(10)
1020 IF IYLL$ = "Y" THEN Y2 = LOG(Y2) / LOG(10)
1100 REM CHANGE THE READINGS TO REAL READINGS
1200 C1 = I1 - I0
1300 C2 = J1 - J0
1400 C3 = SQR(C1 * C1 + C2 * C2)
1500 XXX = C3 / (X1 - X0)
1600 C4 = I2 - I0
1700 C5 = J2 - J0
1800 C6 = SQR(C4 * C4 + C5 * C5)
1900 YYY = C6 / (Y2 - Y0)
2000 REM
2100 REM
2200 REM *** PREP FOR DIGITIZING CURVE ***
2250 CLS
2300 PRINT "WHAT FILE NAME WOULD YOU LIKE TO USE FOR THE DATA?"
2400 INPUT DATA$
2450 DATA1$ = "A:\" + DATA$
2500 OPEN DATA1$ FOR OUTPUT AS #2
2600 REM
2700 CLS
2800 REM BEGIN DIGITIZING
2900 PRINT "ENTER DATA POINTS"
2935 PRINT "*****************"
2950 PRINT "PRESS 'F' BUTTON ON POINTER WHEN DONE "
3000 INPUT #1, I, J, F, P
3001 BEEP
3100 IF F = 16 GOTO 10000
3200 U1 = I - I0
3300 U2 = J - J0
3400 YY = Y0 + ((U2 - U1 * C2 / C1) * C1 / C3) / YYY
3500 XX = X0 + ((U1 - U2 * C4 / C5) * C1 / C3) / XXX
3510 IF IXLL$ = "Y" THEN XX = 10 ^ XX
3520 IF IYLL$ = "Y" THEN YY = 10 ^ YY
3600 WRITE #2, XX, YY
3700 PRINT XX, YY
5000 GOTO 3000
10000 CLOSE #1
10100 CLOSE #2
10200 CLS
11000 PRINT "DATA IS SAVED IN A:\"; DATA$
11100 '
11200 '
11300 '
11400 '
11500 '
11600 '
11700 ' YOU CAN NOW EXIT THE PROGRAM - OR RERUN IT WITH SHIFT-F5
11800 ' FOR ANOTHER DATA SET
12000 END


DIG.BAT

CD\
CD SUMMA
SEND /F DIG.INI
QBASIC DIG2
CD\


Without trying to hunt up the specs on the DrawingBoard III I can see a couple of potential problems here...

Note the lines:
28 ' THIS PROGRAM ASSUMES THAT THE DIGITIZER HAS BEEN
32 ' PRECONFIGURED WITH THE SUMMA SEND COMMAND TO RESPOND
36 ' USING THE COM PARAMETERS BELOW
38 OPEN "COM1:9600,E,7,2" FOR RANDOM AS #1

In order to use this program your DrawingBoard would have to be connected through the COM1 port (normally used for the mouse). You could try to configure the tablet to use "OPEN COM" parameters above (Speed=9600, Parity=E (Even), Data bits per byte=7, Stop bits=2) or you could check the default settings for the tablet and change the "OPEN COM" qbasic code to suite.

Naturally, if the tablet can't use COM1 or COM2, this discussion is moot.

The second problem comes with the lines:

CD\
CD SUMMA
SEND /F DIG.INI
QBASIC DIG2
CD\

After writing a properly formatted INI file for the tablet software it uses a program in the SUMMA directory to "SEND" the data. It then runs another BAS program (I can't guess it's purpose).

I'm not going to step out on the line to say that this probably won't work... but I'm guessing It might turn out to be more difficult than I originally guessed. After offering to help, I'm not going to turn my back now, but it would be difficult to come up with a decent programming solution with having the hardware and manuals in hand.

First, see if the tablet's I/O settings can be configured and whether the software can read the didgitized contents of a file. That will be a good start. I'll snoop around and see what I can find out.

If you need detailed information on using the OPEN COM statement you might post a question in the Microsoft Qbasic forum.

Good luck and check back.




A plain black box

Red Flag This Post

Please let us know here why this post is inappropriate. Reasons such as off-topic, duplicates, flames, illegal, vulgar, or students posting their homework.

Red Flag Submitted

Thank you for helping keep Tek-Tips Forums free from inappropriate posts.
The Tek-Tips staff will check this out and take appropriate action.

Reply To This Thread

Posting in the Tek-Tips forums is a member-only feature.

Click Here to join Tek-Tips and talk with other members! Already a Member? Login

Close Box

Join Tek-Tips® Today!

Join your peers on the Internet's largest technical computer professional community.
It's easy to join and it's free.

Here's Why Members Love Tek-Tips Forums:

Register now while it's still free!

Already a member? Close this window and log in.

Join Us             Close