What is a good Vfp substitute for IsArray()

[justamistere]

In VFP 6, I haven't found any inherent IsArray() function like VB has. I am sending a @param1 to either a Procedure/Method, where I want to test to see if it is array or just a single memory variable.

I have something that may work, hopefully in all situations. I was wondering how others have achieved this common test.

*20*********************************************************
* Name:		IsArray()
* Author:	JXE 2004/10/25
* Description:	Determine if a variable is an array.
* Syntax:	llIsArray = IsArray(@txValue).
************************************************************
FUNCTION IsArray
LPARAMETERS	txMemVar
LOCAL	lcOLD_ErrorHandler, ;
	lnErrorNumber, ;
	llReturnValue

STORE	""	TO	lcOLD_ErrorHandler
STORE	0	TO	lnErrorNumber
STORE	.T.	TO	llReturnValue

lcOLD_ErrorHandler = ON("ERROR")
ON ERROR lnErrorNumber = GetErrorNumber(ERROR())
= ALEN(txMemVar, 1)

***---| "name" is not an array (Error 232)
IF lnErrorNumber = 232
	llReturnValue = .F.
ENDIF

ON ERROR &lcOLD_ErrorHandler
RETURN llReturnValue
************************************************************

*21*********************************************************
* Name:		GetErrorNumber()
* Author:	JXE 2004/10/25
* Description:	Returns the VFP error number returned by
*               the ERROR() function.
************************************************************
FUNCTION GetErrorNumber
LPARAMETER	tnErrorNumber
  LOCAL lnErrorNumber
  lnErrorNumber = tnErrorNumber
RETURN lnErrorNumber
************************************************************

 

[SteveDingle]

Heya justamistere

You should be able to use the TYPE() function. It's what I use. Below is an sample prg.

CLEAR
LOCAL llIsArray,;
      lcTest

*-- Don't pass anything
m.llIsArray = IsArray()
IF m.llIsArray
   ?"#1 Array"
ELSE
   ?"#1 Not Array"
ENDIF  

m.lcTest = ""

*-- Pass text string
m.llIsArray = IsArray(m.lcTest)
IF m.llIsArray
   ?"#2 Array"
ELSE
   ?"#2 Not Array"
ENDIF  

*-- Pass Array
DIMENSION laTest[12,32]
m.llIsArray = IsArray( @laTest )
IF m.llIsArray
   ?"#3 Array"
ELSE
   ?"#3 Not Array"
ENDIF  

RETURN 


*--------------------------------------------------
*) Descript....: Display Parameter Value
*
*  Parameters..: 
*--------------------------------------------------
FUNCTION IsArray( tuValueToTest )
   LOCAL llIsArray

   *-- It's an array if we can see the "element"
   m.llIsArray = ( TYPE( "tuValueToTest[1,1]") <> "U" )

   RETURN m.llIsArray
ENDFUNC

HTH

Toodles,
Steve Dingle

http://www.dsbusinesssolutions.co.uk

D&S Business Solutions Ltd

 

[rgbean]

And for the lurkers, this is all unneccesary in VFP 9.0. The new option on the TYPE() function will return "A" when it's an array!

Rick

 

[Mike Lewis]

Rick,

The new option on the TYPE() function will return "A" when it's an array!

Yes, I remember reading that somewhere. But, as with so many useful new features in 9.0, the developers don't appear to have passed the news to the guys who write the Help file.

Mike


Mike Lewis
Edinburgh, Scotland

My Visual Foxpro web site:

http://www.ml-consult.demon.co.uk

My Crystal Reports web site:

http://www.ml-crystal.com

 

[craigsboyd]

And for the lurkers...

<waves to the lurkers>

http://www.sweetpotatosoftware.com

 

[holzert]

In VFP8 I find it more reliable to use:

IF TYPE('ALEN(myarray,1)')="N"
   *--Is an array
ELSE
   *--Is not an array
ENDIF

 

[craigsboyd]

holzert,

Do you mind expanding on why you find this solution to be "more reliable" than checking for Type() != "U" ? I'm interested, thanks.

http://www.sweetpotatosoftware.com

 

[rgbean]

Mike,
It's in the updated help file in the TYPE() topic - it was released about a week ago. Download it at:

http://www.microsoft.com/downloads/...2a-754b-4f89-bf30-8a1d20f08e8b&displaylang=en

Note: This does document a few features NOT available in the public beta, but will be in the final release, and it still needs additional "fixes" itself. Also, you can get and read this help file even if you don't install VFP 9.0 (beta). That way you can check out the new features by just reading about them. (You may be inspired then to install the public beta to try some of them out!)

Rick

 

[Mike Lewis]

Thanks, Rick. I hand't realised a new Help was available.

Mike


Mike Lewis
Edinburgh, Scotland

My Visual Foxpro web site:

http://www.ml-consult.demon.co.uk

My Crystal Reports web site:

http://www.ml-crystal.com