starting a "Save As" popup form programatically

[VBAguy22]

hello
I am exporting a table from Access to Excel using a button on a form and some VB code. Right now its going to a default directory I specify in TransferSpreadsheet parameter. I want to let the user browse their computer (kind of like Save As option in Excel) and save the file wherever they want, and let them name it whatever they want. Anyone done this before? any code cuts?
thanks!

 

[Nordyck]

Function Export_Excel(tbl As String)
Dim path As Variant
path = BrowseFolder 'Browses the folder

On Error Resume Next
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, tbl, path & "output.xls", True, tbl


End Function


nordycki@hotmail.com

 

[faeryfyrre]

Create a new module and dump the following code in.

See the included function TestIt for details on how to use it.

Option Compare Database
Option Explicit

'***************** Code Start **************
'This code was originally written by Ken Getz.
'It is not to be altered,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
'   Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996

Type tagOPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    strfilter As String
    strCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    strFile As String
    nMaxFile As Long
    strFileTitle As String
    nMaxFileTitle As Long
    strInitialDir As String
    strTitle As String
    Flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    strDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
    Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
    Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function TestIt()
    Dim strfilter As String
    Dim lngFlags As Long
    strfilter = ahtAddFilterItem(strfilter, "Access Files (*.mda, *.mdb)", _
                    "*.MDA;*.MDB")
    strfilter = ahtAddFilterItem(strfilter, "dBASE Files (*.dbf)", "*.DBF")
    strfilter = ahtAddFilterItem(strfilter, "Text Files (*.txt)", "*.TXT")
    strfilter = ahtAddFilterItem(strfilter, "All Files (*.*)", "*.*")
    MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\", _
        filter:=strfilter, FilterIndex:=3, Flags:=lngFlags, _
        DialogTitle:="Hello! Open Me!")
    ' Since you passed in a variable for lngFlags,
    ' the function places the output flags value in the variable.
    Debug.Print Hex(lngFlags)
End Function

Function GetOpenFile(Optional varDirectory As Variant, _
    Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strfilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
    lngFlags = ahtOFN_FILEMUSTEXIST Or _
                ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
    If IsMissing(varDirectory) Then
        varDirectory = ""
    End If
    If IsMissing(varTitleForDialog) Then
        varTitleForDialog = ""
    End If

    ' Define the filter string and allocate space in the "c"
    ' string Duplicate this line with changes as necessary for
    ' more file templates.
    strfilter = ahtAddFilterItem(strfilter, _
                "Access (*.mdb)", "*.MDB;*.MDA")
    ' Now actually call to get the file name.
    varFileName = ahtCommonFileOpenSave( _
                    OpenFile:=True, _
                    InitialDir:=varDirectory, _
                    filter:=strfilter, _
                    Flags:=lngFlags, _
                    DialogTitle:=varTitleForDialog)
    If Not IsNull(varFileName) Then
        varFileName = TrimNull(varFileName)
    End If
    GetOpenFile = varFileName
End Function

Function ahtCommonFileOpenSave( _
            Optional ByRef Flags As Variant, _
            Optional ByVal InitialDir As Variant, _
            Optional ByVal filter As Variant, _
            Optional ByVal FilterIndex As Variant, _
            Optional ByVal DefaultExt As Variant, _
            Optional ByVal filename As Variant, _
            Optional ByVal DialogTitle As Variant, _
            Optional ByVal hwnd As Variant, _
            Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strfilename As String
Dim strFileTitle As String
Dim fResult As Boolean
    ' Give the dialog a caption title.
    If IsMissing(InitialDir) Then InitialDir = CurDir
    If IsMissing(filter) Then filter = ""
    If IsMissing(FilterIndex) Then FilterIndex = 1
    If IsMissing(Flags) Then Flags = 0&
    If IsMissing(DefaultExt) Then DefaultExt = ""
    If IsMissing(filename) Then filename = ""
    If IsMissing(DialogTitle) Then DialogTitle = ""
    If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
    If IsMissing(OpenFile) Then OpenFile = True
    ' Allocate string space for the returned strings.
    strfilename = Left(filename & String(256, 0), 256)
    strFileTitle = String(256, 0)
    ' Set up the data structure before you call the function
    With OFN
        .lStructSize = Len(OFN)
        .hwndOwner = hwnd
        .strfilter = filter
        .nFilterIndex = FilterIndex
        .strFile = strfilename
        .nMaxFile = Len(strfilename)
        .strFileTitle = strFileTitle
        .nMaxFileTitle = Len(strFileTitle)
        .strTitle = DialogTitle
        .Flags = Flags
        .strDefExt = DefaultExt
        .strInitialDir = InitialDir
        ' Didn't think most people would want to deal with
        ' these options.
        .hInstance = 0
        '.strCustomFilter = ""
        '.nMaxCustFilter = 0
        .lpfnHook = 0
        'New for NT 4.0
        .strCustomFilter = String(255, 0)
        .nMaxCustFilter = 255
    End With
    ' This will pass the desired data structure to the
    ' Windows API, which will in turn it uses to display
    ' the Open/Save As Dialog.
    If OpenFile Then
        fResult = aht_apiGetOpenFileName(OFN)
    Else
        fResult = aht_apiGetSaveFileName(OFN)
    End If

    ' The function call filled in the strFileTitle member
    ' of the structure. You'll have to write special code
    ' to retrieve that if you're interested.
    If fResult Then
        ' You might care to check the Flags member of the
        ' structure to get information about the chosen file.
        ' In this example, if you bothered to pass in a
        ' value for Flags, we'll fill it in with the outgoing
        ' Flags value.
        If Not IsMissing(Flags) Then Flags = OFN.Flags
        ahtCommonFileOpenSave = TrimNull(OFN.strFile)
    Else
        ahtCommonFileOpenSave = vbNullString
    End If
End Function

Function ahtAddFilterItem(strfilter As String, _
    strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

    If IsMissing(varItem) Then varItem = "*.*"
    ahtAddFilterItem = strfilter & _
                strDescription & vbNullChar & _
                varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
    intPos = InStr(strItem, vbNullChar)
    If intPos > 0 Then
        TrimNull = Left(strItem, intPos - 1)
    Else
        TrimNull = strItem
    End If
End Function


'To call the actual dialog from your code, see the enclosed function
'TestIt() within the module or use the following example as a guideline and
'
'Dim strFilter As String
'Dim strInputFileName As String
'
'strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.XLS)", "*.XLS")
'strInputFileName = ahtCommonFileOpenSave(Filter:=strFilter, OpenFile:=True, _
'                DialogTitle:="Please select an input file...", _
'                Flags:=ahtOFN_HIDEREADONLY)
'
'+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
'
'Note that in order to call the Save As dialog box,
'you can use the same wrapper function by just setting the OpenFile option as False. For example,
'

'Ask for SaveFileName
'strFilter = ahtAddFilterItem(myStrFilter, "Excel Files (*.xls)", "*.xls")
'strSaveFileName = ahtCommonFileOpenSave(OpenFile:=False, Filter:=strFilter, _
'                    Flags:=ahtOFN_OVERWRITEPROMPT Or ahtOFN_READONLY)

Function AddAllToList(ctl As Control, lngID As Long, lngRow As Long, _
lngCol As Long, intCode As Integer) As Variant
    
    ' Adds "(All)" to the top of a combo box or list box.
    
    ' You can add "(All)" in a different column of the combo box
    ' or list box by setting the control's Tag property to a different
    ' column number, or display text other than "(All)" by appending
    ' a semicolon(;) and the text you want to display. For example,
    ' setting the Tag property to "2;<None>" displays "<None>"
    ' in the second column of the list.
   
      Static dbs As Database, rst As Recordset
      Static lngDisplayID As Long
      Static intDisplayCol As Integer
      Static strDisplayText As String
      Dim intSemiColon As Integer

   On Error GoTo Err_AddAllToList
      Select Case intCode
         Case acLBInitialize
            ' See if function is already in use.
            If lngDisplayID <> 0 Then
               MsgBox "AddAllToList is already in use by another control!"
               AddAllToList = False
               Exit Function
            End If

            ' Parse the display column and display text from Tag property.
            intDisplayCol = 1
            strDisplayText = "(All Outlets)"
            If Not IsNull(ctl.Tag) Then
               intSemiColon = InStr(ctl.Tag, ";")
               If intSemiColon = 0 Then
                  intDisplayCol = Val(ctl.Tag)
               Else
                  intDisplayCol = Val(Left(ctl.Tag, intSemiColon - 1))
                  strDisplayText = Mid(ctl.Tag, intSemiColon + 1)
               End If
            End If

            ' Open the recordset defined in the RowSource property.
            Set dbs = CurrentDb
            Set rst = dbs.OpenRecordset(ctl.RowSource, dbOpenSnapshot)

            ' Record and return the lngID for this function.
            lngDisplayID = Timer
            AddAllToList = lngDisplayID

         Case acLBOpen
            AddAllToList = lngDisplayID

          Case acLBGetRowCount
            ' Return number of rows in recordset.
            On Error Resume Next
            rst.MoveLast
            AddAllToList = rst.RecordCount + 1

         Case acLBGetColumnCount
            ' Return number of fields (columns) in recordset.
            AddAllToList = rst.Fields.count

         Case acLBGetColumnWidth
            AddAllToList = -1

         Case acLBGetValue
            If lngRow = 0 Then
               If lngCol = intDisplayCol - 1 Then
                  AddAllToList = strDisplayText
               Else
                  AddAllToList = Null
               End If
             Else
                rst.MoveFirst
                rst.Move lngRow - 1
                AddAllToList = rst(lngCol)
            End If
         Case acLBEnd
            lngDisplayID = 0
            rst.Close
      End Select

Bye_AddAllToList:
      Exit Function

Err_AddAllToList:
    MsgBox Err.Description, vbOKOnly + vbCritical, "AddAllToList"
    AddAllToList = False
    Resume Bye_AddAllToList
   End Function

Alec Doughty
Doughty Consulting P/L

"Life's a competition. Play hard, but play fair"