Sending email with SMTP 1

[developer155]

Hello, what reference ro componetn shoudl I include with my VB project to use SMTP like the this:

Smtp1.Message.To.Add "you@test.com" ' Specify the recipient
'Smtp1.Message.From = "me@test.com" ' Specify the sender
'Smtp1.Message.Subject = "Test Message" ' Specify the subject
'Smtp1.Message.Text = "This is a test." ' Add message body
'Smtp1.Message.AddAttachment m_szConfirmFileName ' Add attachment
'Smtp1.Login "mail.dart.com" ' Start the mail session
'Smtp1.send ' Send message
'Smtp1.Logout ' End session

thanks a lot!!!

 

[fredericofonseca]

You need a SMTP component.

Now which one will depends on what control was used on the program using that bit of code.

It looks like DART by PowerTCP, but it may not be that one.

Regards

Frederico Fonseca
SysSoft Integrated Ltd

http://www.syssoft-int.com

 

[developer155]

Is there one that comes in Visual Basic?

thanks

 

[fredericofonseca]

hit the send button too soon.

Another possibility is to use the vbsendmail control which is free, and is available at

http://www.freevbcode.com/ShowCode.Asp?ID=109

Regards

Frederico Fonseca
SysSoft Integrated Ltd

http://www.syssoft-int.com

 

[goodfela26]

Another good one to use it Ostrosoft SMTP Component.

http://www.ostrosoft.com/smtp_component/smtp_vb.asp

---------------------------------------
Bob Beck
IS Administrator

 

[developer155]

Guys! Is there SMTP component that comes with VB? I do not want any third party

thanks

 

[fredericofonseca]

No there isn't, but the one I mentioned is free and you get the source, so I don't see what is the problem.


Regards

Frederico Fonseca
SysSoft Integrated Ltd

http://www.syssoft-int.com

 

[dilettante]

Well, you can just use CDO if you have Windows 2000 or later:

Option Explicit 
'Project requires a reference to: 
' "Microsoft CDO for Windows 2000 Library" 

Dim objMessage As New CDO.Message 

Sub Configure(ByVal strServer As String) 
    'Configure for your SMTP server. 
     
    With objMessage.Configuration.Fields 
      .Item(cdoSendUsingMethod) = cdoSendUsingPort 
      .Item(cdoSMTPUseSSL) = False 
      .Item(cdoSMTPServer) = strServer 
      .Item(cdoSMTPServerPort) = 25 
      .Item(cdoSMTPConnectionTimeout) = 60 
      .Item(cdoSMTPAuthenticate) = cdoAnonymous 
      .Update 
    End With 
End Sub 

Sub SendEmail(ByVal strSubj As String, _ 
              ByVal strFrom As String, _ 
              ByVal strTo As String, _ 
              ByVal strText As String) 
    With objMessage 
      .Subject = strSubj 
      .From = strFrom 
      .To = strTo 
      .TextBody = strText 
     
      .Send 
    End With 
End Sub 

Sub Main() 
    Configure "mail.mymail.com" 
    On Error Resume Next 
    SendEmail "Example CDO message", _ 
              """Bill Williams"" <billw@mymail.com>", _ 
              """Robert Finkbeinder"" <Bob@bob.com>", _ 
              "Hello Bob, this is an automated message" & _ 
              " from Bill," & vbNewLine & _ 
              "sent via CDO." 
    If Err.Number = 0 Then 
      MsgBox "Complete!" 
    Else 
      MsgBox "Error &H" & Hex(Err.Number) & vbNewLine & _ 
             Err.Description 
    End If 
End Sub

 

[strongm]

>Is there SMTP component that comes with VB?
>No there isn't,

Well, as Dilettante illustrates, whilst VB doesn't come with a pure SMTP component, every OS from W2K onwards does - W2K, XP, W2K3 (depending on what you have installed, the library may be called Microsoft CDO for Exchange 2000 instead of Microsoft CDO for Windows 2000; the former is a superset of the latter)

 

[developer155]

What about using the MAPI control?

thanks

 

[strongm]

The MAPI controls require that you have to have had a MAPI client installed* (to provide a MAPI profile, including such info as where your Exchange Server is; if you ain't got a server then the MAPI controls won't help you). Furthermore, they are fairly restricted, being based on the somewhat ancient Simple MAPI


* OK, not quite true. The requirement is that enough has been installed to provide a MAPI profile (which provides the necessary ifo to create a Session). The easiest way to do this is by installing something like Outlook, but MS do provide downloadable tools that just generate MAPI profiles that will work with the MAPI controls