Return field number of string in a line 1

[stackdump]

How do I determine which field a string is within a line?

e.g. "Hello how are you"

I want to find out the position of the word "how", which for this example is field 2.

 

[p5wizard]

You have to loop through all the fields until found
something like:

awk '{
for (i=1;i<=NF;i++) {
if ($i=="how") {
print
print "field number " i "is \"how\""
break
}
}
}' /path/to/inputfile


HTH,

p5wizard

 

[stackdump]

ok, this more difficult than I first thought.

I'm processing a file that permits continuation lines. I need to extract the parameter after one that I know is definitely there.

a b c d KnownString TheValue e f

or it could be some combination like;
a b c d
+ KnownString
+ TheValue e
+ f

So I can match the line to see if KnownString is present. Then see if TheValue parameter is on the same line. If not look to the next line and take the second parameter.

Any help appreciated.

 

[futurelet]

BEGIN { target = "KnownString" }

/^\+/ { sub( /^\+/, "" ); line = line $0 ; next }

{ process( line )
  line = $0
}
END { process( line ) }

function process( line )
{
  split( line, ary, /[ \t]+/ )
  for (i=1; i in ary; i++)
  { if (target == ary[i])
      print ary[i+1]
  }
}

 

[stackdump]

Jeepers! Well your code is a lot shorter than the mess I've created so far! Thanks, have a star too.

 

[futurelet]

Glad you liked it.