Passing Variables

rbri · Nov 21, 2002

Hello Everyone
I am trying to write a little utility using hta as the GUI for vbscript. I am trying to pass a variable form one function to another function in the same program. here is my code

'-----------------------------------------------------------
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim objShell

Set objShell = CreateObject("WScript.shell&quot

'-----------------------------------------------------------

Function builddir(strChgDir)

Dim strCmd1, strDir

strDir = strChgDir
If strDir = "" Then
strDir = "H:\"
End If
strCmd1 = "cmd.exe /C dir /B /A

/S " & strDir & " >C:\Temp\tmpdirlist.txt"
objShell.run strCmd1, 1, TRUE

End Function

'-----------------------------------------------------------

Function chngdir()

Dim strChgDir

strChgDir = InputBox("Enter new Drive letter to Browse&quot

MsgBox "You are going to Browse " & strChgDir

End Function

'-----------------------------------------------------------

'Call builddir() Function to execute
builddir(strChgDir)

'-----------------------------------------------------------

I get an error with this code. The debugger reports that I have an undefined variable and the spot where I call the function to execute is highlighted by the debugger. If I attempt to define this variable in the builddir() function I get a different error message "Name Redefined" and the debugger highlights the Dim line in the builddir() function. Any help someone can give to me will be greatly appreciated.

Thanks Randy

dilettante · Nov 21, 2002

I can't tell where this script is sitting in your HTA. It looks like you want to excute

Code:

builddir(strChgDir)

before the page has finished loading though. Is this true?

Also, you don't seem to have a variable called

Code:

strChgDir

to pass to

Code:

builddir()

. All I see is the formal parameter in the definition of

Code:

builddir()

.

So, yeah, the debugger is right. At the point where you perform this function call there isn't anything called

Code:

strChgDir

.

Plus, you declared functions, but then do sub calls to them. For that matter you aren't assigning return values in your functions either.

This is probably the wrong site to come to if you are trying to start out learning VBScript. Have you tried resources like

http://www.w3schools.com/vbscript/vbscript_intro.asp

?

rbri · Nov 22, 2002

Both functions are setting at the beginning of the program
in the header section. The variable strChgDir is initialized in the chngdir() function located just below the builddir() function. Here is the whole program

<HTML>
<HEAD>
<HTA:APPLICATION
ID = "oApp"
APPLICATIONNAME = "HTA Application Tag 2001"
BORDER = "thick"
CAPTION = "yes"
ICON = "H:\rbri_VBScript\ugutil.ico"
SHOWINTASKBAR = "yes"
SINGLEINSTANCE = "yes"
SYSMENU = "yes"
WINDOWSTATE = "normal"
SCROLL = "yes"
SCROLLFLAT = "yes"
VERSION = "1.0"
INNERBORDER = "yes"
SELECTION = "no"
MAXIMIZEBUTTON = "yes"
MINIMIZEBUTTON = "yes"
NAVIGABLE = "yes"
CONTEXTMENU = "yes"
BORDERSTYLE = "normal"
>

<SCRIPT Language="VBScript">
<!--
' Author:- Randy Briggin
' Date:- Nov. 21, 2002
' Description:- This program executes UG programs through an hta interface
' Comments:-
Option Explicit

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim strMsg1, objFso, objShell, strUgFlex
Public strChgDir

Set objFso = CreateObject("Scripting.FileSystemObject&quot

Set objShell = CreateObject("WScript.shell&quot

strUgFlex = "UGII_LICENSE_FILE=27000@flfe1ia0.flt.acr.gmeds.com"

'--------------------------------------------------------------------------------

Function builddir()

Dim strCmd1, strDir

strDir = strChgDir
If strDir = "" Then
strDir = "H:\"
End If
strCmd1 = "cmd.exe /C dir /B /A

/S " & strDir & " > C:\Temp\tmpdirlist.txt"
objShell.run strCmd1, 1, TRUE

End Function

'---------------------------------------------------------------------------------

Function chngdir()

' Dim strChgDir

strChgDir = InputBox("Enter new Drive letter to Browse&quot

MsgBox strChgDir

End Function

'---------------------------------------------------------------------------------

Function chk()

strMsg1 = "Looks Good"
MsgBox strMsg1

End Function

'----------------------------------------------------------------------------------

builddir()

-->
</SCRIPT>
</HEAD>
<BODY>
<CENTER>
<marquee ALIGN="Center" LOOP="infinite" BEHAVIOR="slide"
BGCOLOR="#FFFFFF" DIRECTION="left" HEIGHT=30 WIDTH=100>
<H1><FONT color=#0000FF>Delphi</FONT></H1>
</marquee>
</CENTER>
<H1><CENTER>Unigraphics Utility Menu</CENTER></H1>
<HR>
<BR>
<FORM NAME=ugutil>
<TABLE COLUMNS="2">
<TD ALIGN="left" VALIGN="top">
<LEFT>
<FIELDSET STYLE="font-size:20px; WIDTH:227px;">
<LEGEND><FONT size=5 color=blue>ACTIONS</FONT></LEGEND><BR>
&nbsp&nbsp&nbsp<SPAN STYLE="color:green;" ONCLICK="chk()">Inspect Partfile Structure</SPAN><BR>
&nbsp&nbsp&nbsp<SPAN STYLE="color:green;" ONCLICK="chk()">Inspect Partfile</SPAN><BR>
&nbsp&nbsp&nbsp<SPAN STYLE="color:green;" ONCLICK="chk()">Convert Partfile</SPAN><BR><BR><BR>
&nbsp&nbsp&nbsp<SPAN STYLE="color:red;" ONCLICK="chk()">Exit</SPAN>
<BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR>
</FIELDSET>
</LEFT>
</TD>
<TD ALIGN="center" VALIGN="middle">
<H3>Directory&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbspFiles<BR>&nbsp&nbsp
<SELECT NAME="dirlist" SIZE=11>
<SCRIPT LANUAGE=VBSCRIPT>
Dim strLine, objFso, strFileDirLst, objShell, aFileContests, strVar, strChkVar
Set objFso = CreateObject("Scripting.FileSystemObject&quot

Set strFileDirLst = objFs

penTextFile("C:\Temp\tmpdirlist.txt", 1)
aFileContents = Split(strFileDirLst.ReadAll, vbCrLf)
For Each strLine In aFileContents
strVar = "<OPTION VALUE=" & strLine & ">" & strLine & "</OPTION>"
Document.Write strVar
Next
</SCRIPT>
</SELECT>&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp&nbsp
<SELECT NAME="filelist" SIZE=11>
<OPTION VALUE="FILE1">File one</OPTION>
<OPTION VALUE="FILE">File two</OPTION>
<OPTION VALUE="FILE">File three</OPTION>
</SELECT><BR><BR><BR><BR>
<INPUT TYPE="Submit" VALUE=" Change Drive " onclick=chngdir()><BR>
<INPUT TYPE="Submit" VALUE="Browse Directory" onclick=chk()><BR>
</TD>
</FORM>
</BODY>
</HTML>

Thanks Randy

dilettante · Nov 25, 2002

I'm lost here.

I have:
[ul][li]pasted your code into a blank .hta file,
[li]edited out the ICON line 'cause I didn't have it,
[li]changed the start drive letter to C:\ 'cause I've no H:\ drive here
[li]Change cmd.exe to command.com 'cause I'm testing under Win98SE on this machine[/ul]
Works fine. Well there are still bugs I guess, but I get no script errors and it loads up that listbox with the DIRs from my C:\ drive.

I'm stumped. What's broken?

By the way, why run a CMD.EXE DIR instead of using the FSO to retrieve directory and file names?

rbri · Dec 2, 2002

Hello

The above code also works fine for me because the directory is harded coded in. The problem I have and the errors I receive are when I attempt to change directories. I can't seem to pass the variable from the chngdir() function to the builddir() function. Why I used cmd instead of FSO. I thought it would be easier to create and populate my select box in the body of the html code.

Thanks Randy

dilettante · Dec 3, 2002

Ok, I looked at it again, and now I see what I saw before. I guess I assumed this was a bug you already knew about.

You have a blob of inline script in the body of your document that gets executed during page-load. How were you hoping this would get executed a second (third, etc.) time?

Basically, I have doubts that your use of document.write() at load-time is the way to go to build your SELECT list.

Oh! I finally figured out why your page is doing anything at all. "Change Drive" is a SUBMIT button.

You have the page submitting back to itself, causing a page-reload, and thus invoking all of your script all over again. Wondered why the page was blanking out.

Hmm, this sure is a different way to build an HTA.

You could do it this way I guess, but it isn't the usual way I've seen HTAs structured. You're going to lose anything your page's 1st incarnation has "learned" when it dies and enters its 2nd incarnation after clicking one of those SUBMIT buttons.

If you really want to do it this way... well, you're going to have to pass info from one page to another through some mechanism. A text file? Query parameters? Something.

Most HTAs I've seen are built more like a VB program, responding to events and taking actions that way, like repopulating a SELECT list at run-time, not just at load time.

What you have here is the HTA equivalent of a program that takes some input, then triggers another run of itself and dies.

I'm not saying it's wrong (who can say that?) but it isn't an approach I'd consider. Sort of like shelling DIR to examine the directory. Way slow and clunky. If your HTA gets very complex it'll be a nightmare passing state info between "runs" of your "program."

HTA programming is not transactional like ASP development for example is. An HTA is normally more procedural or even conversational, again more like a VB program than a "web" application. The basic idea is more like a WSH script with a GUI.

rbri · Dec 3, 2002

Hello

I should explain I am new to vbscript and hta I have more experience in UNIX scripting perl posix etc. This is what I am trying to do. I am trying to use hta as a GUI interface only to execute several command line programs. My thought was on load of the hta it would display a list of directories residing in the users home directory including the home directory in the left select window. Plus a listing of all the files in the home directory in the right select window. On the far left is a list of command line programs that the user chooses to use. After the hta program is executed and displayed on the screen the user would then either pick a file from the right window or pick a directory pick the browse directory button then pick a file from the new listing in the right window. After picking the file the user would then pick what command line program they wanted to execute against the file they picked.
In the event that the file they wanted was not under thier home directory structure then they would need to change directories and that is where my problem is. I am not aware of another way to populate the select list and I don't know how to dynamically change the contents of a select list without using a submit button and reload the page. If you can direct me to a book that can help me better learn hta
and vbscript I would greatly appreciate that.

Thanks Randy

dilettante · Dec 3, 2002

I'd love to oblige you Randy, but I haven't found a single book with anything but a cursory treatment of HTAs.

My own theory is that hardly anybody writes HTAs.

One issue is the nasty press they've gotten because HTAs can be exploited for certain nasty purposes, though in reality a desktop-resident HTA is no more dangerous than any other Windows application.

Another is that most desktop scripters don't have the DHTML skills to write them, 'cause they aren't "web johnnies."

And those with the web skills needed just aren't that interested in creating desktop applications. Most HTAs are just that - desktop applications, or web-enabled desktop applications.

So here we are...

Maybe I can help by posting your HTA with some changes to make it do more of what you'd like? I've kept a lot of it intact, and sorta raped the rest. Sorry about that.

If you copy/paste this into a blank HTA file and try it, you'll see what I mean.

Note that I have it defaulting to C:\ for testing instead of the G:\ or whatever you have above. Just change the cosntant I added near the top of the page code.

Also note the event handler at the end of the script block called window_onload(), this gets called as soon as the page finishes loading.

I've also used VBScript-style event-handler linking for the button clicks (no longer SUBMIT buttons) instead of the JavaScript-style handler lashup you were using (onclick="..." type syntax). This is done by naming the Function or Sub something like "button_onclick()."

Note also that while event handlers CAN be Functions, this is only used to return an event-cancel indication when (rarely) needed. In most cases these oughta be Subs instead as shown here. In VBScript a Function is used to return a result.

Ok, blah, blah, blah... I hope this gives you an idea anyway though. There just isn't a lot published on HTAs, but if you find something be sure to mention it back here.

<HTML>
<HEAD>
<HTA:APPLICATION
ID = "oApp"
APPLICATIONNAME = "HTA Application Tag 2001"
BORDER = "thick"
CAPTION = "yes"
SHOWINTASKBAR = "yes"
SINGLEINSTANCE = "yes"
SYSMENU = "yes"
WINDOWSTATE = "normal"
SCROLL = "yes"
SCROLLFLAT = "yes"
VERSION = "1.0"
INNERBORDER = "yes"
SELECTION = "no"
MAXIMIZEBUTTON = "yes"
MINIMIZEBUTTON = "yes"
NAVIGABLE = "yes"
CONTEXTMENU = "yes"
BORDERSTYLE = "normal"
>

<SCRIPT Language="VBScript">
<!--
' Author:- Randy Briggin
' Date:- Nov. 21, 2002
' Description:- This program executes UG programs through an hta interface
' Comments:-
Option Explicit

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const cstrDefaultDir = "C:\"
Dim strMsg1, objFso, objShell, strUgFlex
Dim strChgDir

Set objFso = CreateObject("Scripting.FileSystemObject&quot

Set objShell = CreateObject("WScript.shell&quot

strUgFlex = "UGII_LICENSE_FILE=27000@flfe1ia0.flt.acr.gmeds.com"

'--------------------------------------------------------------------------------

Sub builddir()
Dim lngOption, folStart, folEach, filEach, objOption

For lngOption = ugutil.selFileList.length - 1 To 0 Step -1
ugutil.selFileList.options.remove(lngOption)
Next

For lngOption = ugutil.selDirList.length - 1 To 0 Step -1
ugutil.selDirList.options.remove(lngOption)
Next

Set folStart = objFSO.GetFolder(strChgDir)
For Each folEach In folStart.SubFolders
Set objOption = document.createElement("option&quot

objOption.value = strChgDir & folEach.Name & "\"
objOption.text = strChgDir & folEach.Name & "\"
ugutil.selDirList.options.add objOption
Next

For Each filEach In folStart.Files
Set objOption = document.createElement("option&quot

objOption.value = filEach.Name
objOption.text = filEach.Name
ugutil.selFileList.options.add objOption
Next

Set objOption = Nothing
Set filEach = Nothing
Set folEach = Nothing
Set folStart = Nothing
End Sub

'--------------------------------------------------------------------------------

Sub btnBrowseDir_onclick()
strChgDir = ugutil.selDirList.value
builddir
End Sub

'---------------------------------------------------------------------------------

Sub btnChgDrive_onclick()
strChgDir = InputBox("Enter new Drive letter to Browse&quot

If strChgDir = "" Then
strChgDir = cstrDefaultDir
Else
strChgDir = Left(strChgDir, 1) & ":\"
End If
builddir
End Sub

'---------------------------------------------------------------------------------

Function chk()

strMsg1 = "Looks Good"
MsgBox strMsg1

End Function

'----------------------------------------------------------------------------------

Sub window_onload()
strChgDir = cstrDefaultDir
builddir
End Sub
-->
</SCRIPT>
</HEAD>
<BODY>
<CENTER>
<marquee ALIGN="Center" LOOP="infinite" BEHAVIOR="slide"
BGCOLOR="#FFFFFF" DIRECTION="left" HEIGHT=30 WIDTH=100>
<H1><FONT color=#0000FF>Delphi</FONT></H1>
</marquee>
</CENTER>
<H1><CENTER>Unigraphics Utility Menu</CENTER></H1>
<HR>
<BR>
<FORM NAME=ugutil>
<TABLE COLUMNS="2">
<TD ALIGN="left" VALIGN="top">
<LEFT>
<FIELDSET STYLE="font-size:20px; WIDTH:227px;">
<LEGEND><FONT size=5 color=blue>ACTIONS</FONT></LEGEND><BR>
<SPAN STYLE="color:green;" ONCLICK="chk()">Inspect Partfile Structure</SPAN><BR>
<SPAN STYLE="color:green;" ONCLICK="chk()">Inspect Partfile</SPAN><BR>
<SPAN STYLE="color:green;" ONCLICK="chk()">Convert Partfile</SPAN><BR><BR><BR>
<SPAN STYLE="color:red;" ONCLICK="chk()">Exit</SPAN>
<BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR><BR>
</FIELDSET>
</LEFT>
</TD>
<TD ALIGN="center" VALIGN="middle">
<H3>Directory Files<BR>
<SELECT id="selDirList" SIZE=11>
</SELECT>
<SELECT id="selFileList" SIZE=11>
</SELECT><BR><BR><BR><BR>
<INPUT type="button" id="btnChgDrive" value=" Change Drive "><BR>
<INPUT type="button" id="btnBrowseDir" value="Browse Directory"><BR>
</TD>
</FORM>
</BODY>
</HTML>

Good luck!

rbri · Dec 4, 2002

Hello

WOW I've got alot to learn! I would have never thought to code those select lists that way but thats exactly what I was trying to accomplish. Thank you very much for your time and help! That helped and showed me alot.

Thanks Randy

Tek-Tips is the largest IT community on the Internet today!

Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!

Passing Variables

rbri

Programmer

dilettante

MIS

rbri

Programmer

dilettante

MIS

rbri

Programmer

dilettante

MIS

rbri

Programmer

dilettante

MIS

rbri

Programmer

Similar threads

Part and Inventory Search

Sponsor