Opening to specific record: Code not working, Please HELP 1

[jasonmac]

Hello everyone. I must say this has completely frustrated me. I'm using acces '97 and I'm trying to open a form to a specific record.

This is the code that I am using to initially open the form

Private Sub Command18_Click()
    If Me.NewRecord Then
        MsgBox "Please enter a tool number to continue.", vbOKOnly, "APQP Warning"
        Exit Sub
    End If
    
    DoCmd.OpenForm "sbfrmCommentsTooling", acNormal, , , , , Forms!sbfrmActionItems!sbfrmTooling!txtID.Value

End Sub

And this is the code I'm using when the form opens to find the specific record.

Private Sub Form_Open(Cancel As Integer)
Dim rec As Recordset
DoCmd.Restore
    
    Set rec = Me.RecordsetClone
    
    If rec.RecordCount < 1 Then
        DoCmd.GoToRecord , , acNewRec
        Me!txtIDvalue.Value = Me.OpenArgs
    Else
    
        rec.FindFirst [ID] = Me.OpenArgs

        If rec.NoMatch Then
            DoCmd.GoToRecord , , acNewRec
            Me!txtIDvalue.Value = Me.OpenArgs
        Else
            Me.Bookmark = Me.RecordsetClone.Bookmark
        End If
    End If
    
End Sub

The Problem is that even when there is a matching record it still creates a new record. Can anyone tell me what I'm doing wrong here??

 

[RoyVidar]

It might have to do with having the code in the form open event, where the form recordset might not be fully loaded yet.

You might try using the forms on load event in stead. I'd also try adding some quotes on the .FindFirst:

[tt]rec.FindFirst "[ID] =" & Me.OpenArgs[/tt]

and change the last line to:

[tt]Me.Bookmark = rec.Bookmark[/tt]

I'm a bit careful myself, and like to also perform a check on the openargs, if not isnull(me.openargs) then..., and perhaps some conversion:

[tt]rec.FindFirst "[ID] =" & clng(Me.OpenArgs)[/tt]

Roy-Vidar

 

[jasonmac]

That worked like a charm Roy. Thanks!