multiple home folders?

[Deeem]

Hi,

I know that you can create a home folder for the users in their profile tab, but can you make more than one.

i.e. S: = \\server\staff
T: = \\server\backups

Regards
Damon

 

[mikiemov]

Yes, this can be done using login scripts. Create a file with the bat extension, along the lines of:

net use S: \\server\data

Save this file to the netlogon folder, then set this as a login script in the profiles tab.

Mike,

 

[Deeem]

Thanks for that.

Damon

 

[markdmac]

I'd use VBScript instead of the bat and deploy it within a GPO. Performance at login is better with VBS (I think because it does not require the initialization of a VM). VBScript is also a lot more flexible.

Here is a sample you can use. It is well commented so you should be able ot tweak it without trouble.

'==========================================================================
'
' NAME: LogonScript.vbs
'
' AUTHOR:  Mark D. MacLachlan, The Spider's Parlor
' URL   : [URL unfurl="true"]http://www.thespidersparlor.com[/URL]
' DATE  : 4/10/2003
'
' COMMENT: Enumerates current users' group memberships in given domain.
'
'==========================================================================


ON ERROR RESUME NEXT

Set WSHShell = CreateObject("WScript.Shell")
Set WSHNetwork = CreateObject("WScript.Network")

'Edit the next line with your domain name
DomainString = "DomainName"
UserString = WSHNetwork.UserName
'Bind to the user object to get user name and check for group memberships later
Set UserObj = GetObject("WinNT://" & DomainString & "/" & UserString)

'Synchronizes the time with Server our NTP Server
WSHShell.Run "NET TIME \\Server /set /y"

'Disconnect any drive mappings as needed.
WSHNetwork.RemoveNetworkDrive "F:"

'Give the PC time to do the disconnect, wait 300 milliseconds
wscript.sleep 300

'Map drives needed by all
WSHNetwork.MapNetworkDrive "U:", "\\server\users",True
WSHNetwork.MapNetworkDrive "X:", "\\server\executables",True

'Now check for group memberships and map appropriate drives
For Each GroupObj In UserObj.Groups
	Select Case GroupObj.Name
	'Check for group memberships and take needed action
	'In this example below, ADMIN and WORKERB are groups.
		Case "Admin"
			WSHNetwork.MapNetworkDrive "w:", "\\Server\Admin Stuff",True
		Case "WorkerB"
			WSHNetwork.MapNetworkDrive "w:", "\\Server\Shared Documents",True
	End Select
Next


'Install Printers

WSHNetwork.AddWindowsPrinterConnection "\\Server\HP5si"

'Clean Up Memory We Used
set UserObj = Nothing
set GroupObj = Nothing
set WSHNetwork = Nothing
set DomainString = Nothing
set WSHSHell = Nothing

'Quit the Script
wscript.quit

I hope you find this post helpful. Please let me know if it was.

Regards,

Mark

 

[mikiemov]

I havent spent a lot of time looking at vbs scripts, but I will certainly take a look...

Thanks