Form activation???

[ii128]

Hi all,

I have a big problem. I would like to pop up a message when someone open a form and doesn't do anything in 10 min. How can I do that??? It likes kind of the windows password if you leave the computer for awhile, then the password screen pops up.

 

[dumdum]

Yeah, Here's some help. I use this all over my database in various forms to remind my people to close what they're doing. 2 procedures here
------------------------------------
Private Sub Form_Timer()

' IDLEMINUTES determines how much idle time to wait for before
' running the IdleTimeDetected subroutine.
Const IDLEMINUTES = 2


Static PrevControlName As String
Static PrevFormName As String
Static ExpiredTime

Dim ActiveFormName As String
Dim ActiveControlName As String
Dim ExpiredMinutes

On Error Resume Next

' Get the active form and control name.

ActiveFormName = Screen.ActiveForm.Name
If Err Then
ActiveFormName = "No Active Form"
Err = 0
End If

ActiveControlName = Screen.ActiveControl.Name
If Err Then
ActiveControlName = "No Active Control"
Err = 0
End If

' Record the current active names and reset ExpiredTime if:
' 1. They have not been recorded yet (code is running
' for the first time).
' 2. The previous names are different than the current ones
' (the user has done something different during the timer
' interval).

If (PrevControlName = "&quot Or (PrevFormName = "&quot _
Or (ActiveFormName <> PrevFormName) _
Or (ActiveControlName <> PrevControlName) Then
PrevControlName = ActiveControlName
PrevFormName = ActiveFormName
ExpiredTime = 0
Else
' ...otherwise the user was idle during the time interval, so
' increment the total expired time.
ExpiredTime = ExpiredTime + Me.TimerInterval
End If

' Does the total expired time exceed the IDLEMINUTES?
ExpiredMinutes = (ExpiredTime / 1000) / 60
If ExpiredMinutes >= IDLEMINUTES Then
' ...if so, then reset the expired time to zero...
ExpiredTime = 0
' ...and call the IdleTimeDetected subroutine.
IdleTimeDetected ExpiredMinutes
End If
End Sub
----------------------------------------------------
Sub IdleTimeDetected(ExpiredMinutes)
MsgBox &quot;There has been no user activity with&quot; & vbCrLf & &quot;this form in the last 2 &quot; & _
&quot;minutes. Please&quot; & vbCrLf & &quot;close the form if you are through!&quot;, vbInformation + _
vbOKOnly + vbDefaultButton1, &quot;Inactivity Alert&quot;
End Sub

 

[ii128]

dumdum,

Do I need to change any form properties because it doesn't work for me. it doesn't pop up the message?

 

[dumdum]

Sorry, you'll need to set the timer interval to 1000 in the form properties sheet. Also make sure you have [event procedure] shown in the properties sheet too.

It should work. I took a look at the code again and the above should get you rolling.