Enable Vista Verbose Messages Logon/Logoff 1

[markdmac]

Tired of looking at Please Wait while Vista starts up or shuts down. You can enable Verbose messages that will give you detailed information on what is going on behind the scenes.

The following KB shows how to configure this (KB was for 2003 but same settings on Vista)

http://support.microsoft.com/kb/325376/

Since I enjoy scripting everything, I wrote a script to do the job for me. Thought I would share.

[green]
'==========================================================================
'
' NAME: EnableVistaVerboseMessages.vbs
'
' AUTHOR: Mark D. MacLachlan , The Spiders Parlor
' DATE  : 06/20/2007
'
' COMMENT: Enables verbose login messages on Vista.
'          This script and many more can be found in the
'          Admin Script Pack by The Spider's Parlor
'          [URL unfurl="true"]http://www.thespidersparlor.com/vbscript[/URL]
'
'    THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT WARRANTY OF
'    ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO
'    THE IMPLIED WARRANTIES OF MERCHANTABILITY AND/OR FITNESS FOR A
'    PARTICULAR PURPOSE.
'
'    IN NO EVENT SHALL THE SPIDER'S PARLOR AND/OR ITS RESPECTIVE SUPPLIERS 
'    BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR ANY
'    DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS,
'    WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS
'    ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE
'    OF THIS CODE OR INFORMATION.
'
'==========================================================================[/green]

On Error Resume Next
Const HKEY_LOCAL_MACHINE = &H80000002
strComputer = "."
[green]
'First verify that strComputer is running Vista
[/green]
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select Caption from Win32_OperatingSystem",,48)
For Each objItem in colItems
    If InStr(objItem.Caption,"Vista") Then
                
	    RegBasePath= "SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System"
	                                    
	    Set oReg=GetObject( _
	        "winmgmts:{impersonationLevel=impersonate}!\\" &_ 
	        strComputer & "\root\default:StdRegProv")[green]
	    'Enable Verbose Messages[/green]
	    strValueName = "verbosestatus"
	    oReg.SetDWORDValue _ 
	        HKEY_LOCAL_MACHINE,RegBasePath,strValueName,1[green]
	    'Make sure all messages are not being suppressed.    [/green]
	    strValueName = "DisableStatusMessages"
	    oReg.GetDWORDValue HKEY_LOCAL_MACHINE,RegBasePath,strValueName,dwValue
	    [green]
	    'If dwValue = 1 then messages are turned off.  Enable them.[/green]
	    If dwValue = 1 Then
			oReg.SetDWORDValue _ 
	        	HKEY_LOCAL_MACHINE,RegBasePath,strValueName,0
	    End If
	    [green]
	    'Check for errors.[/green]
	    If Err = 0 Then
	        WScript.Echo "Verbose messages enabled"
	    Else 
	       WScript.Echo "Error enabling verbose messages." & _
	           vbCrLf & "Error:" & Err.Number
	    End If
    Else
            WScript.Echo objItem.Caption & " detected.  This script is only intended for Vista."
            Wscript.Quit       
    End If
Next

I hope you find this post helpful.

Regards,

Mark

Check out my scripting solutions at

http://www.thespidersparlor.com/vbscript

Work SMARTER not HARDER. The Spider's Parlor's Admin Script Pack is a collection of Administrative scripts designed to make IT Administration easier! Save time, get more work done, get the Admin Script Pack.