Copy a file with vbs (by modified, name)

[RNF0528]

Need to adjust Script to copy a specific file name.

There are many files in the folder.
I need to copy the ones that start with a name of "Batch*.html" and have been modified today.

I tried to add a \batch* to the CONST Path but it will not go.

Here is the code.
------------------------------------------------------------
Option Explicit

CONST PATH = "C:\Documents and Settings\Administrator\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data"

Dim strDate_2_Copy, strShare
Dim fso, objFolder, colFiles, objFile, strFile

Set fso = CreateObject("Scripting.FileSystemObject")

strDate_2_Copy = Date
strShare = "C:\EmailReport\"

If fso.FolderExists(PATH) Then
Set objFolder = fso.GetFolder(PATH)
Set colFiles = objFolder.Files
Else
Wscript.Echo "Can't find the " & PATH & " folder"
Wscript.Quit
End if

For Each strFile in colFiles
Set objFile = fso.GetFile(strFile)
If DateDiff("d", objFile.DateLastModified, strDate_2_Copy) = 0 Then
fso.CopyFile strFile, strShare & "\GPSBackup.log" , True
' Wscript.Echo strFile.Name & ", Mod-Date: " & objFile.DateLastModified & ", copied to " & strShare
End If
Set objFile = Nothing
Next


Wscript.Quit
------------------------------------------------------------

 

[PHV]

You may try this:
For Each strFile in colFiles
If Int(strFile.DateLastModified) = Int(Date) _
And Left(LCase(strFile.Name,5)="batch") _
And Right(LCase(strFile.Name,5)=".html" Then
fso.CopyFile strFile, strShare & "\GPSBackup.log" , True
Exit For
End If
Next

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[RNF0528]

Will this allow me to use the * wilcard?

The reason i ask is becuase batch is just the begining of the filename?

ie. batch-12-6543-JUL-2006

 

[PHV]

And Left(LCase(strFile.Name,5)="batch") _

 

[RNF0528]

Error Message:

Wrong number of arguments or invalid property Assignment:'LCase"

Thanks Agian for the help!!

 

[PHV]

OOps, sorry for the typos :~/
For Each strFile in colFiles
If Int(strFile.DateLastModified) = Int(Date) _
And Left(LCase(strFile.Name),5)="batch" _
And Right(LCase(strFile.Name),5)=".html" Then
fso.CopyFile strFile, strShare & "\GPSBackup.log" , True
Exit For
End If
Next

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[RNF0528]

Works Great Thanks agian!