API method or instruction

[madhatter2002]

Does anybody know how to get the Hard disk serial number using VFP???

 

[wgcs]

How about this:
( Notice that this returns a number representing the serial number of the drive, But the DIR command shows it in HEX, hyphenated between two WORDs )

FUNCTION GetSerialNumber
LPARAMETERS pcDrive
DECLARE SHORT GetVolumeInformation IN kernel32; 
    STRING    lpRootPathName,; 
    STRING  @ lpVolumeNameBuffer,; 
    INTEGER   nVolumeNameSize,; 
    INTEGER @ lpVolumeSerialNumber,; 
    INTEGER @ lpMaximumComponentLength,; 
    INTEGER @ lpFlags,; 
    STRING  @ lpFileSystemNameBuffer,; 
    INTEGER   nFileSystemNameSize 

*!*	BOOL GetVolumeInformation(
*!*	  LPCTSTR lpRootPathName,           // root directory
*!*	  LPTSTR lpVolumeNameBuffer,        // volume name buffer
*!*	  DWORD nVolumeNameSize,            // length of name buffer
*!*	  LPDWORD lpVolumeSerialNumber,     // volume serial number
*!*	  LPDWORD lpMaximumComponentLength, // maximum file name length
*!*	  LPDWORD lpFileSystemFlags,        // file system options
*!*	  LPTSTR lpFileSystemNameBuffer,    // file system name buffer
*!*	  DWORD nFileSystemNameSize         // length of file system name buffer
*!*	)
LOCAL lcDrive, lcVolName,lnSerialNum,lnComp,lnFlags,lcFileSystemName
lcDrive     = iif(vartype(pcDrive)='C',pcDrive,Set('DEFAULT'))
do case
  case len(lcDrive)=1
    lcDrive = lcDrive + ':\'
  case len(lcDrive)=2
    lcDrive = lcDrive + '\'
endcase  
lcVolName   = space(100)
lnSerialNum = 0
lnComp      = 0 
lnFlags     = 0
lcFileSystemName = space(100)

IF 0=GetVolumeInformation( lcDrive, @lcVolName, 100, ;
        @lnSerialNum, @lnComp, @lnFlags, @lcFileSystemName, 100 )
  lnSerialNum = 0xFFFFFFFF
endif
return lnSerialNum
ENDFUNC

 

[madhatter2002]

Thanks wgcs,

would either of you have something for the win95/98 os that can also work with other versions of windows??

 

[wgcs]

What's a "different thing"? It is the same number shown to me when I go to that drive and type "DIR"... only the DIR command shows it at the top in Hex and a Hyphen, for example, my C: drive DIR listing shows:

 Volume in drive C has no label.
 Volume Serial Number is 3912-8833

 Directory of C:
02/23/2000  09:48a      <DIR>          WINNT
02/23/2000  09:51a      <DIR>          Documents and Settings

etc...

and GetSerialNumber("C:&quot returns 957515827, which, if you use any hexadecimal-capable calculator, is represented in hex as "39128833" ... add the hyphen, and it's identical. The drive serial number is just a DWORD numeric value.

As for Win98, the MSDN documentation on the GetVolumeInformation function says:

  Windows NT/2000 or later: Requires Windows NT 3.1 or later.
  Windows 95/98/Me: Requires Windows 95 or later.
  Header: Declared in Winbase.h; include Windows.h.
  Library: Use Kernel32.lib.
  Unicode: Implemented as Unicode and ANSI versions on Windows NT/2000.

 

[DSummZZZ]

Just a side note. ?0x39128833 returns 957515827, so you can use:

STORE STR(0x39128833) TO nSerial
?nSerial

Dave S.

 

[rgbean]

Just to add to this discussion, I discovered a freeware .DLL a while back, that will give you the "real" physical disk serial number - not the easily changed logical disk serial number. I've posted it and a sample usage .PRG at our local user group web site -

http://mmfudg.lansing.com/files/DetDiskSerial.zip.

Note: If you go to

http://vip.6to23.com/songdai/reg_DiskSerial.html

there seems to be a similar DLL (but different - a later version?) to the one I was using - it has "nag" messages if you don't register it. You just have to read a bit of Chinese (or at least between the lines! ).

Rick

 

[DSummZZZ]

Here's another way to get the serial number I stumbled across:

fso = CreateObject("Scripting.FileSystemObject&quot
nSerial = fso.GetDrive(fso.GetDriveName('C:')).SerialNumber
?nSerial
Dave S.