anti-virus auto update across NT4 network (batch files ?)

[harnet]

I'm trying to find out a way of automatically updateing virus definition files across a NT4 network of about 80-100 workstations, and I haven't got much of a clue but its my job (long story).
They're using NT4 with no service packs, Norton AV and I think they also have Dr. Solomon installed aswell.
I know its possible as it used to happen in my old company in UK, but if you answer please bear in mind that I'm in a developing country and resources are very limited & download speeds would make you all weep.
thanks.

sorry, also in general virus discussion forum

 

[djhawthorn]

We have this in place, only we use McAfee Virus Scan.

The script we use is as follows - you'll need to modify it so it works for your AV software though.

========================

@echo off
REM **************************************************************************
REM Update McAfee DAT Files
REM **************************************************************************

REM ==========================================================================
REM Setup Variables and Check for the Operating System.
REM ==========================================================================

set OldDATversion=DAT-4207.tok
set NewDATversion=DAT-4210.tok
set SourceDir=\\server2\Updates

if "%OS%" == "Windows_NT" goto WinNT
goto Win95



REM ==========================================================================
REM Windows 95 Update
REM ==========================================================================
:Win95
REM --------------------------------------------------------------------------
REM If McAfee isn't installed, or is already updated, then we are done.
REM --------------------------------------------------------------------------
if not exist "C:\Program Files\Network Associates\McAfee VirusScan\scan.dat" goto End
if exist %windir%\%NewDATversion% goto End


echo ********************************************************
echo * *
echo * Updating McAfee DAT Files - Please Wait... *
echo * *
echo ********************************************************

if exist %windir%\%OldDATversion% del %windir%\%OldDATversion%
%SourceDir%\setup.exe /SILENT /LOGFILE %windir%\%NewDATversion%

goto End



REM ==========================================================================
REM Windows NT Update
REM ==========================================================================
:WinNT
REM --------------------------------------------------------------------------
REM If McAfee isn't installed, or is already updated, then we are done.
REM --------------------------------------------------------------------------
if not exist "C:\Program Files\Network Associates\VirusScan\vshwin32.exe" goto End
if exist %SystemRoot%\%NewDATversion% goto End


echo ********************************************************
echo * *
echo * Updating McAfee DAT Files - Please Wait... *
echo * *
echo ********************************************************

if exist %SystemRoot%\%OldDATversion% del %SystemRoot%\%OldDATversion%
%SourceDir%\setup.exe /SILENT /LOGFILE %SystemRoot%\%NewDATversion%

goto End



:End
REM ==========================================================================
REM Unset the variables used and we are done.
REM ==========================================================================
set OldDATversion=
set NewDATversion=
set SourceDir=


========================

Then we just edit the two vars at the top of the login script everytime we update the DAT file on server2. MCSE NT4/W2K

 

[hchman]

Norton Anti-Virus Corporate Edition will do this for you automatically on Win NT and 2000 machines.