Retrieve computer share name from a drive letter?

Question

Retrieve computer share name from a drive letter?

Webrookie (Programmer)

(OP)

17 Aug 00 09:16

say I have "h:\" mapped to "\\computername\bobsdrive"

What is the proper code to go about retrieving the name?
I want to retrieve "\\computername\bobsdrive"

Do I have to go about using API?

Could someone help me out with this one?

jonscott8 (Programmer) · Answer 1 · 2000-08-17 10:51:55

I'd use the Windows Scripting Host.
Something like this:

FUNCTION GetUNCPath
  LPARAMETERS tcMappedDriveLetter

  LOCAL lcRetPath,WshNetwork,oDrives,i

  lcRetPath = '
  IF TYPE('tcMappedDriveLetter')<>'C'
    RETURN lcRetPath
  ENDIF
  tcMappedDriveLetter=LEFT(tcMappedDriveLetter,1)
  IF !DIRECTORY(tcMappedDriveLetter+':')
    RETURN lcRetPath
  ENDIF

  WshNetwork = CREATEOBJECT("WScript.Network")
  oDrives = WshNetwork.EnumNetworkDrives

  *NOTE: this array is 0 based
  FOR i = 0 To oDrives.Count - 1
    IF oDrives.Item(i)=tcMappedDriveLetter
      lcRetPath=oDrives.Item(i+1)
      EXIT
    ENDIF
  ENDFOR

  RETURN lcRetPath
ENDFUNC

If you can't use the WSH for whatever reasons, you can still do it with the API. I just prefer the WSH. :-)

Jon Hawkins
jonscott8@yahoo.com

Carpe Diem! - Seize the Day!

Webrookie (Programmer) · Answer 2 · 2000-08-17 12:44:03

Thank you Jon for your reply...I'm sure we can use WSH, but who knows. We're gonna try it now.....

I'll let you know.

:)

Webrookie (Programmer) · Answer 3 · 2000-08-17 17:03:05

Awesome Jon...You are a genius! Thank you very much

jonscott8 (Programmer) · Answer 4 · 2000-08-18 11:50:48

Awesome Jon...You are a genius!

LOL. Thanks. I'd been down the mapped drive path before, so it was fairly easy for me to recollect.

Thank you very much

You're welcome. Glad I could help.

Jon Hawkins
jonscott8@yahoo.com

Carpe Diem! - Seize the Day!

Come Join Us!

Posting Guidelines

Retrieve computer share name from a drive letter?