Swapping Image *Positions* 1

Let's start with the simplest example: swap locations of two objects.

The set up:
Place one object in Sprite 1, another object in Sprite 2. Place "Swap" button in Sprite 3.

The scripts:
1. Movie script:
[tt]--
on prepareMovie
global gSwapPList
gSwapPList = [:]
end prepareMovie
--[/tt]

2. Behaviour script attached to the "Swap" button:
[tt]--
on mouseUp me
global gSwapPList
if gSwapPList.length < 1 then
gSwapPList = [#1: [#sprite: 1, #x: sprite(1).locH, #y:sprite(1).locV], #2: [#sprite: 2, #x: sprite(2).locH, #y: sprite(2).locV]]
end if
end mouseUp
--[/tt]

3. Frame script:
[tt]--
on exitFrame me
global gSwapPList
if gSwapPList.count > 1 then
spriteA = sprite(gSwapPlist[#1][#sprite])
spriteATargetLocH = gSwapPlist[#2][#x]
spriteATargetLocV = gSwapPlist[#2][#y]
if spriteA.locH <> spriteATargetLocH then
spriteA.locH = spriteA.locH + (spriteATargetLocH - spriteA.locH)/10
end if
if spriteA.locV <> spriteATargetLocV then
spriteA.locV = spriteA.locV + (spriteATargetLocV - spriteA.locV)/10
end if
spriteB = sprite(gSwapPlist[#2][#sprite])
spriteBTargetLocH = gSwapPlist[#1][#x]
spriteBTargetLocv = gSwapPlist[#1][#y]
if spriteB.locH <> spriteBTargetLocH then
spriteB.locH = spriteB.locH + (spriteBTargetLocH - spriteB.locH)/10
end if
if spriteB.locV <> spriteBTargetLocV then
spriteB.locV = spriteB.locV + (spriteBTargetLocV - spriteB.locV)/10
end if
end if
go the frame
end
--[/tt]

Kenneth Kawamoto

Dear Kenneth:

Apologies for the one-week delay---I got sidetracked by totally unrelated projects...

Returning to this matter today, I found your post to be very smart, clean, simple, clear, and (as it turns out), highly effective.

It has served not only to solve my problem but as a Lingo programming lesson all of its own. It has helped me to deepen my understanding of how Lingo works with lists, handlers, etc. I am extremely grateful.


Warmest regards,

Adam LeBow
Los Angeles, CA, USA