'start another thread to show how to add controls from another thread
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
    System.EventArgs) Handles MyBase.Load
        Dim t1 As New System.Threading.Thread(AddressOf thread1)
        t1.Start()
    End Sub

    Private Sub thread1()
        'Define a textbox to add
        Dim textbox1 As New TextBox
        textbox1.Location = New Point(50, 50)
        textbox1.Multiline = True
        textbox1.Width = 300
        textbox1.Height = 250
        textbox1.Text = "blah"
        'call a special sub to add the control as
        'we are not allowed to add controls directly
        AddControlToForm(textbox1)
    End Sub

    ' prototype for the delegate
    Private Delegate Sub AddControlToFormDelegate(ByVal ctrl As Control)

    Private Sub AddControlToForm(ByVal ctrl As Control)
        'Add string control ctrl to form me

        'InvokeRequired lets us know if we are in the wrong thread to
        'access form Me
        If Me.InvokeRequired Then
            ' make a delegate that will fire this sub again
            Dim delegate1 As New AddControlToFormDelegate(AddressOf _
        AddControlToForm)
            ' hold the parameters - the control being sent
            Dim parameters(0) As Object
            parameters(0) = ctrl
            'Ask form me to call this sub using the delegate with the parameters.
            Me.Invoke(delegate1, parameters)
            'it will call from the correct thread
        Else
            'InvokeRequired lets us know we are in the correct thread
            'so we can use listview1.add safely
            Me.Controls.Add(ctrl)
        End If
    End Sub