Windows XP config to Netware 4

[tgoodman]

I'm getting ready to install a XP pro box to a netware environment. It's been awhile and was wondering if any had any tips. If I remember correctly, I need to install CSNW. But, what about joining the domain etc...

Any help or ideas would be greatly appreciated.

Thanks

Thanks for your responses!

 

[lgarner]

I think you'll have better luck with Novell's client than with CSNW. Computers don't join anything with NetWare, access is user-based. Just fill in the fields for tree, context & user. Your Netware server should also be in DNS to resolve the tree name, or use another method to locate it. Since there's no "domain", computers need another way to locate servers. SLP and DNS are most popular.

 

[Rick998]

tgoodman,

I agree with lgarner... use the Novell Client. We have 1200 workstations (mostly XP Pro) attached to 25-odd Novell 4.12 and Novell 5 servers.

After much trial and error, my own suggestions are:

1) Use the latest Novell Client 32 (v4.90 SP2e... but be aware that it's still buggy and an even newer version is currently in beta).

2) Run 'setupnw.exe' to start the installer.

3) Do a 'Custom' install, not 'Typical' install.

4) Don't include anything except the Client (top option) unless you really, really need to.

5) Don't add 'NMAS', 'NICI' or 'NetIdentity' unless you need to.

6) Use 'IP and IPX' in preference to 'IP with IPX Compatibility' if IPX is supported on your network. (We're not yet IP-only and have had major problems with 'IP with IPX Compatibility'. We've had to revert back to 'IP and IPX' after slow or failed logons, missing network drives and 'disconnected network drive' errors.)

7) After installation of the Client has finished, don't allow automatic re-boot. Instead, just close the installer then open the Novell Client's 'Properties'.

8) On the default 'Client' tab, consider changing the 'First Network Drive' from F to at least G. [We partition our HD's as C: (Main) and D: (Backup - for the XP cab files, drivers, etc. This means the CDROM drive is E:. When we attach a USB keydrive it wants to be F:... already allocated by Client 32 to a network drive by default]

9) If you want, you can set the preferred Server and and Tree on the 'Client' tab (although we've found it much easier to let roaming users do it themselves from the 'Advanced' button on the login dialog).

10) On the 'Advanced Login' tab, turn 'NMAS Authentication' from 'On' (default) to 'Off' otherwise login process will be slower. (See the notes for more info) At work we log users into the Win XP workstation first (using TweakUI's autologon for ease of use) so we also change 'Initial Novell Login' from 'On' (default) to 'Off' to surpress the Novell login dialog. When Windows loads (and user is logged into Windows XP automatically) then we pop up the Novell login dialog using a shortcut in the Windows Startup folder. Works for us but your setup may be very different.

11) Go through the list of parameters on the 'Advanced Menu Settings' tab and consider turning off some of the more daft default settings. (Do you really want users to be able to send messages to each other? Do you really want users to be able to purge files from your server?)

12) On the 'Advanced Settings' tab, I suggest turning 'File Caching' from 'On' (default) to 'Off' and 'File Commit' from 'Off' (default) to 'On'. This has resolved (for us, anyway) a well-known and much discussed opportunistic file locking problem with MS Office files, primarily Excel spreadsheets, stored on a Novell server which results in users getting 'access denied' errors or only being able to open them as 'read-only'. Microsoft say this is fixed in Win XP SP2... we're sticking with Win XP SP1a for the moment.

13) On the 'Default Capture' tab, I suggest removing the checkmark against 'Notify' (in 'Other Setting' area) unless you really want a popup every single time a print job is sent.

Now re-boot...

All the changes above take place in the Registry so consider encapsulating them into a .REG file or VBS script that can be run after installation of the Client. It's well worth the time spent if you have a lot of workstations to configure.

Let me know if you want me to see a VBS script that runs the Client installer then tweaks the registry then re-boots the PC. It was written for Client 32 v4.90 and hasn't yet been updated for 4.90 SP2e but it will give you an idea where the relevant settings are stored in the Registry.

Hope this helps...

Rick

 

[jimp56]

Nice job, Rick998

 

[bcastner]

A star for Rick998 as well.

One thing you want to be certain of is the version of Netware running.

Check to be sure you are not in a pre-4.x.x setting, or in other words, one that is still Bindery-based. You need to make a choice when you run the Custom Install of the Netware Client software.

 

[aquias]

Rick, VERY nicely done. I have to say I think you nailed everything on the head. One thing I disagree with is

At work we log users into the Win XP workstation first (using TweakUI's autologon for ease of use) so we also change 'Initial Novell Login' from 'On' (default) to 'Off' to surpress the Novell login dialog. When Windows loads (and user is logged into Windows XP automatically) then we pop up the Novell login dialog using a shortcut in the Windows Startup folder. Works for us but your setup may be very different.

Personal opinion on not allowing people access to the machine unless they are supposed to have access to it (IE. using the windows login to block unauthorized system access).

My way of handling this is a bit different than yours (and causes more administration unfortunately). Create the users locally that will be logging into the system. Then go and apply this setting [link]http://support.novell.com/cgi-bin/search/searchtid.cgi?/10057660.htm[/url].

This allows you the ability synchronize the local and Netware login no matter which user is currently logging on. One limitation to this is, however, if that you utilize any kind of "Log of" or fast user switching options you will receive the second (windows/Novell) login prompt.

And Rick, as another user in a WinXP/Netware 4.x.x enviroment I'd enjoy taking a look at the VBScript, if you don't mind. It would save me some extra time and digging.

 

[Rick998]

Hi aquias,

I understand your personal opinion but, in our organisation, if you actually get to a PC then you have already proved several times over that you are authorised.

I won't bore you with the additional security requirements I had to meet 'cos I was only painting a very broad stroke for the original poster, tgoodman.

My reply was only suggestions that may (or may not) have been of help... nothing more.

We (the organisation I work for) don't use individual local Win XP user accounts. I'm not at liberty to add any further details re: security except that our XP workstations are just dumb terminals and security is handled elsewhere.

PS - The link you supplied to a Novell TID didn't work.

Regards,

Rick

 

[Rick998]

tgoodman - I forgot to mention using NCIMAN.EXE (found in the 'admin' folder of the Client installer) to create an UNATTEND.TXT file. See

http://support.novell.com/cgi-bin/search/searchtid.cgi?/10017868.htm

for further info. It's just as useful as a VBS script for configuring the Novell Client automatically.

aquias - I forgot to include the VBS script you asked for. It's very simple but does the job....

'===========================================================================
'	Script name	: client32-smart-install-xp.vbs
'	OS			: Windows XP only
'	Amendments	: 22-11-2004 Updated for Client 32 v4.90 SP2e
'===========================================================================
'	PURPOSE
'	This script carries out the following function(s):-
'	1)	Runs the installer.
'	2)	Sets the first network drive to G:.
'	3)	Removes the red Novell icon in the Notification Area.
'	4)	Unchecks the print 'Notify' Option.
'	5)	Amends other (stupid) default registry settings.
'	6)	Writes additional settings to the registry.
'	7)	Checks/amends the Start menu and Startup folder.
'	8)	Re-boots the PC so the changes take effect.
'===========================================================================
Option Explicit 'Enforce definition of variables

' Declare variables
Dim WSH, FSO, ThisPC, objWMIService, objOperatingSystem, colOperatingSystems
Dim oFile1, oFile2, oFile3, rMenu, rSoft, rSys, sTitle, sDone, sWarn, sVer

'Setup scripting environment
Set WSH = Wscript.CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")

'Set File variables - used to shorten path statements
oFile1 = "C:\Documents And Settings\All Users\Start Menu\Programs\Novell (Common)\Novell Send Message.lnk"
oFile2 = "C:\Documents and Settings\All Users\Start Menu\Programs\Novell (Common)\ReadMe.lnk"
oFile3 = "C:\Documents and Settings\All Users\Start Menu\Programs\Novell (Common)\Novell Login.lnk"

'Set Registry variables - used to shorten path statements
rSoft = "HKLM\SOFTWARE\Novell\"
rMenu = "HKLM\SOFTWARE\Novell\Network Provider\Menu Items\"
rSys = "HKLM\SYSTEM\CurrentControlSet\Services\NetwareWorkstation\Parameters\"

'Set String variables
sVer = "v1.0.1"
sTitle = "Client 32 Smart Install " & sVer
sDone = "OK, Client 32 has been installed and fixed..."
sWarn = "Do NOT click on the 'Reboot' button at the end of the installation. " & _
"Instead, click on the 'Close' button so this script can amend the registry. " & _
"Click on the OK button to continue."

'Set target PC variable for WMI
ThisPC = "."

'Section 1 ------------------------------------------------------------
'Show popup warning
WSH.Popup sWarn,0,sTitle,64

'Run the installer and make the script wait till the installer is finished
WSH.Run "D:\client32v49sp2e\setupnw.exe",,True

'Section 2 ------------------------------------------------------------
'Set first network drive to G: - Default was F:
WSH.RegWrite "HKLM\SOFTWARE\Novell\Parameters\First Network Drive", 7, "REG_DWORD"

'Section 3 ------------------------------------------------------------
'Disable 'Show Novell System Tray Icon' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Systray Icon", "NO"

'Section 4 ------------------------------------------------------------
'Disable popup message when print job is finished
WSH.RegWrite rSoft & "Network Provider\Capture Flags\Notify", 0, "REG_DWORD"

'Section 5 ------------------------------------------------------------
'Disable 'Enable Login Administration' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Login Administration", "NO"

'Disable 'Show User Administration Menu' - Default was YES (On)
WSH.RegWrite rMenu & "Enable User Info", "NO"

'Disable 'Enable NetWare Copy Dialog' - Default was YES (On)
WSH.RegWrite rSoft & "Enable NetWare Copy Dialog", "NO"

'Disable 'Enable NetWare Utilities' - Default was YES (On)
WSH.RegWrite rMenu & "Enable NetWare Utilities", "NO"

'Disable 'Enable Send Message Dialog' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Send Message Dialog", "NO"

'Disable 'Enable Send Message to User Dialog' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Send Message to User Dialog", "NO"

'Disable 'Enable Password Administration' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Password Administration", "NO"

'Disable 'Enable Purge Dialog' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Purge Dialog", "NO"

'Disable 'Enable Salvage Dialog' - Default was YES (On)
WSH.RegWrite rMenu & "Enable Salvage Dialog", "NO"

'Disable 'Show Edit Login Script' item - Default was YES (On)
WSH.RegWrite rMenu & "Modify Login Script", "NO"

'Section 6 ------------------------------------------------------------
'Disable Initial Novell Login
WSH.RegWrite rSoft & "NWGINA\PassiveMode", 1, "REG_DWORD"

'Disable NMAS authentication
WSH.RegWrite rSoft & "Login\NMAS Authentication", 0, "REG_DWORD"

'Disable display of NetWare Information Page
WSH.RegWrite rSoft & "Network Provider\Property Pages\Display NetWare Information Page", "NO"

'Fix opportunistic file locking problem with MS Office files stored on server
WSH.RegWrite rSys & "File Caching", 0, "REG_DWORD"
WSH.RegWrite rSys & "File Commit", 1, "REG_DWORD"

'Section 7 ------------------------------------------------------------
If FSO.FileExists(oFile1)Then FSO.DeleteFile oFile1, True
If FSO.FileExists(oFile2)Then FSO.DeleteFile oFile2, True
If FSO.FileExists(oFile3)Then FSO.CopyFile oFile3, "C:\Documents and Settings\All Users\Start Menu\Programs\Startup\", True

'Section 8 ------------------------------------------------------------
'Reboot the PC using WMI
WSH.Popup "Re-booting the PC so changes take effect. Please wait...",2, sTitle 'Inform user
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate,(Shutdown)}!\\" & ThisPC & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    objOperatingSystem.Reboot()
Next

'===========================================================================
'Release resources
'Clear objects from memory to free up resources
Set WSH = Nothing
Set FSO = Nothing
'Quit 'cos you're done!
Wscript.Quit()

The last block, i.e. from 'Release resources' onwards, are just part of a default script template and aren't required for this script.

Hope this helps...

Rick