Return all dates between to dates

[r2d22y]

Hello

I would be very glad if anyone could help me to solve this problem.

I have a "start date" and an "end date" now I need to get all dates between those days stored in an array (@dates)...has all the dates included ("start date" .. all dates between.. "end date")

How is that done using PERL?

Regards/D_S

 

[ishnid]

Here's one suggestion, based on the Date::Calc module:

#!/usr/bin/perl -w
use strict;
use Date::Calc qw(:all);

# set start and end dates
my $start_date = '2005-04-21';
my $end_date = '2006-01-01';

# this will store our result
my @all_dates;

# we'll keep adding days to this until we hit the end date
my @to_check = split /-/, $start_date;

# this is the date to end at, in usable format
my @last = split /-/, $end_date;

# while we're before the end date
while( Delta_Days( @to_check, @last ) >= 0 ) {
   # add to @all_dates
   push @all_dates,  sprintf( "%04d-%02d-%02d", @to_check );

   # go onto the next day
   @to_check = Add_Delta_Days( @to_check, 1 );
}

# print 'em all out.
print "$_\n" for @all_dates;

 

[r2d22y]

Thank you very much, it works perfectly!