Opening Access database problem 1

[jgarnick]

Is there a way to allow an Access database to only be opened once on a user's desktop? In other words, if they have a copy open, but minimized, I don't want them to open the database a second time. When they click on the shortcut to the database on their desktop, I would like their minimized version to come up. Is this possible?

Thanks-- [sig]<p>jgarnick<br><a href=mailto:jgarnick@aol.com>jgarnick@aol.com</a><br><a href= > </a><br> [/sig]

 

[rhicks]

Go to the location below. Maybe this information will help you.

http://www.mvps.org/access/api/api0041.htm

HTH X-)
RDH [sig]<p>Ricky Hicks<br><a href=mailto: rdhicks@mindspring.com> rdhicks@mindspring.com</a><br><a href= > </a><br> [/sig]

 

[jgarnick]

Thanks, it was a lot of code I didn't quite understand--I think I'll just stick with my message box to warn the user to check to see if it is minimized! Unless someone else has an easier idea? [sig]<p>jgarnick<br><a href=mailto:jgarnick@aol.com>jgarnick@aol.com</a><br><a href= > </a><br> [/sig]

 

[rhicks]

The code I pointed you to is overkill for your situation, but it looks for more than just Access. For your app a good portion of the unnecessary code could be eliminated.

Just a thought, (-:
RDH [sig]<p>Ricky Hicks<br><a href=mailto: rdhicks@mindspring.com> rdhicks@mindspring.com</a><br><a href= > </a><br> [/sig]

 

[jgarnick]

I appreciate your help! Do you know which portion of the code I would need to use and where I would put it?? Opening the table in excl mode is out of the question--

Thanks again-- [sig]<p>jgarnick<br><a href=mailto:jgarnick@aol.com>jgarnick@aol.com</a><br><a href= > </a><br> [/sig]

 

[rhicks]

I had not used the code, so I tried it:

Copy the all of the following and paste all to a New empty module(all bold lines below).
Name the module whatever you want.


'********************** Start Code *********************
' Module mdlCheckMultipleInstances
' © Graham Mandeno, Alpha Solutions, Auckland, NZ
' This code may be used and distributed freely on the condition
' that the above credit is included unchanged.

Private Const cMaxBuffer = 255

Private Declare Function apiGetClassName Lib &quot;user32&quot; _
Alias &quot;GetClassNameA&quot; _
(ByVal hWnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) _
As Long

Private Declare Function apiGetDesktopWindow Lib &quot;user32&quot; _
Alias &quot;GetDesktopWindow&quot; _
() As Long

Private Declare Function apiGetWindow Lib &quot;user32&quot; _
Alias &quot;GetWindow&quot; _
(ByVal hWnd As Long, _
ByVal wCmd As Long) _
As Long

Private Const GW_CHILD = 5
Private Const GW_HWNDNEXT = 2

Private Declare Function apiGetWindowText Lib &quot;user32&quot; _
Alias &quot;GetWindowTextA&quot; _
(ByVal hWnd As Long, _
ByVal lpString As String, _
ByVal aint As Long) _
As Long

Private Declare Function apiSetActiveWindow Lib &quot;user32&quot; _
Alias &quot;SetActiveWindow&quot; _
(ByVal hWnd As Long) _
As Long

Private Declare Function apiIsIconic Lib &quot;user32&quot; _
Alias &quot;IsIconic&quot; _
(ByVal hWnd As Long) _
As Long

Private Declare Function apiShowWindowAsync Lib &quot;user32&quot; _
Alias &quot;ShowWindowAsync&quot; _
(ByVal hWnd As Long, _
ByVal nCmdShow As Long) _
As Long

Private Const SW_SHOW = 5
Private Const SW_RESTORE = 9

Public Function winGetClassName(hWnd As Long) As String
Dim sBuffer As String, iLen As Integer
sBuffer = String$(cMaxBuffer - 1, 0)
iLen = apiGetClassName(hWnd, sBuffer, cMaxBuffer)
If iLen > 0 Then
winGetClassName = left$(sBuffer, iLen)
End If
End Function

Public Function winGetTitle(hWnd As Long) As String
Dim sBuffer As String, iLen As Integer
sBuffer = String$(cMaxBuffer - 1, 0)
iLen = apiGetWindowText(hWnd, sBuffer, cMaxBuffer)
If iLen > 0 Then
winGetTitle = left$(sBuffer, iLen)
End If
End Function

Public Function winGetHWndDB(Optional hWndApp As Long) As Long
Dim hWnd As Long
winGetHWndDB = 0
If hWndApp <> 0 Then
If winGetClassName(hWndApp) <> &quot;OMain&quot; Then Exit Function
End If
hWnd = winGetHWndMDI(hWndApp)
If hWnd = 0 Then Exit Function
hWnd = apiGetWindow(hWnd, GW_CHILD)
Do Until hWnd = 0
If winGetClassName(hWnd) = &quot;ODb&quot; Then
winGetHWndDB = hWnd
Exit Do
End If
hWnd = apiGetWindow(hWnd, GW_HWNDNEXT)
Loop
End Function

Public Function winGetHWndMDI(Optional hWndApp As Long) As Long
Dim hWnd As Long
winGetHWndMDI = 0
If hWndApp = 0 Then hWndApp = Application.hWndAccessApp
hWnd = apiGetWindow(hWndApp, GW_CHILD)
Do Until hWnd = 0
If winGetClassName(hWnd) = &quot;MDIClient&quot; Then
winGetHWndMDI = hWnd
Exit Do
End If
hWnd = apiGetWindow(hWnd, GW_HWNDNEXT)
Loop
End Function

Public Function winCheckMultipleInstances(Optional fConfirm As Boolean = True) As Boolean
Dim fSwitch As Boolean, sMyCaption As String
Dim hWndApp As Long, hWndDb As Long
On Error GoTo ProcErr
sMyCaption = winGetTitle(winGetHWndDB())
hWndApp = apiGetWindow(apiGetDesktopWindow(), GW_CHILD)
Do Until hWndApp = 0
If hWndApp <> Application.hWndAccessApp Then
hWndDb = winGetHWndDB(hWndApp)
If hWndDb <> 0 Then
If sMyCaption = winGetTitle(hWndDb) Then Exit Do
End If
End If
hWndApp = apiGetWindow(hWndApp, GW_HWNDNEXT)
Loop
If hWndApp = 0 Then Exit Function
If fConfirm Then
If MsgBox(sMyCaption & &quot; is already open&quot; & vbNewLine _
& &quot;Do you want to open a second instance of this database?&quot;, _
vbYesNo Or vbQuestion Or vbDefaultButton2) = vbYes Then Exit Function
End If
apiSetActiveWindow hWndApp
If apiIsIconic(hWndApp) Then
apiShowWindowAsync hWndApp, SW_RESTORE
Else
apiShowWindowAsync hWndApp, SW_SHOW
End If
Application.Quit
ProcEnd:
Exit Function
ProcErr:
MsgBox Err.Description
Resume ProcEnd
End Function
'********************** End Code *********************


Now build a Macro and name it &quot;Autoexec&quot; (without the quotes).

In this macro choose Run Code as the Action. Then in the Function Name for the macro type in:

winCheckMultipleInstances()

This is all you need to do. If you still have problems, let me know and I will email you the sample db where I have done this as an example.

HTH
RDH

[sig]<p>Ricky Hicks<br><a href=mailto: rdhicks@mindspring.com> rdhicks@mindspring.com</a><br><a href= > </a><br> [/sig]

 

[jgarnick]

Thanks! You're the best! I'll try it out-- [sig]<p>jgarnick<br><a href=mailto:jgarnick@aol.com>jgarnick@aol.com</a><br><a href= > </a><br> [/sig]