Julian date 1

[NotSQL]

Can anyone give me a bit of code that allows me to convert todays date into a julian date format?

Regards

 

[earthandfire]

Something like this?

dim d
dim i
d = date
i = (year(d) - 1900) * 1000 + date - cdate("31/12/" & year(d) - 1)
msgbox(i)

Hope this helps.

 

[NotSQL]

That works fine Earth and Fire, however, if you think your good how would i convert the first day of the month into a julian date format?

 

[earthandfire]

Try:

dim d
dim i
d = cdate("1/" & month(date) & "/" & year(date))
i = (year(d) - 1900) * 1000 + d - cdate("31/12/" & year(d) - 1)
msgbox(i)

Hope this helps

 

[dilettante]

This example uses documented functions provided for the purpose and avoids (1.) unnecessary string concatentation and (2.) localization timebombs in the string representations of dates:

Option Explicit

Dim dtToday
Dim intJToday
Dim dt1stOfMonth
Dim intJ1stOfMonth

Function DateToJulian(ByVal DateVal)
  'Convert native Date format to an
  'Integer of the form YYYYDDD.
  DateToJulian = Year(DateVal) * 1000 _
               + DatePart("y", DateVal)
End Function

dtToday = Date()

intJToday = DateToJulian(dtToday)
MsgBox "Today: " & CStr(intJToday)

dt1stOfMonth = DateSerial(Year(dtToday), Month(dtToday), 1)

intJ1stOfMonth = DateToJulian(dt1stOfMonth)
MsgBox "First of this month: " & CStr(intJ1stOfMonth)