Group Policies for locally logged in PCs

[kingjames]

I'm a group policy novice with a GPO issue. I need to get locally logged on XP workstation to pick up group policies from AD, Is this possible?

This is what I've done so far,
The workstations are on the domain
I created and edited the new policy with the windows update settings
created an OU for the workstations and linked the GP
moved the workstations into the OU

the result has been;
only workstations picking up the new wsus setting are the workstation inwhich AD users log on to the domain.

Is there any way to get out the policy with out a user loggin into the domain?

 

[bobsa32]

Have you created account for all the computers in your domain. Im a bit of a GPO novice myself, however we were installing a new piece of software to all our pc's and managed to do it using GPO, it installed the sofware on startup before the user had logged on. So i am assuming that the computer verified itself against the domain, which triggered the install of the software. I would have to assume therefore that the computer picked up the group policy.

 

[krenkey]

The next time the station log's off and log's on the gpo's will be refreshed. Or you can go to the station and type gpupdate and it will do it on that station or from the server you can do a gpupdate /f and that will force all stations to get new gpo's

 

[markdmac]

Rebooting your PCs will also force a GP Update. You can remotely reboot workstations via vbscript. Let me know if you need a script to do that.

I hope you find this post helpful.

Regards,

Mark

 

[krenkey]

HEHEH actually mark that script would be usefull under certain cirmstances if you would be so kind as to post it so i can have a look see.

 

[markdmac]

this version of the script will read a list of workstation names and reboot them remotely. Save this code to a file called RebootWSFromList.vbs.

Create a text file called WSLIST.TXT. Place the two in the same location and double click the script.

'==========================================================================
'
' NAME: RebootWSfromList.vbs
'
' AUTHOR: Mark D. MacLachlan , The Spider's Parlor
' URL: [URL unfurl="true"]http://www.thespidersparlor.com[/URL]
' DATE  : 7/6/2004
'
' COMMENT: <comment>
'
'==========================================================================

On Error Resume Next

'open the file system object
Set oFSO = CreateObject("Scripting.FileSystemObject")
set WSHShell = wscript.createObject("wscript.shell")
'open the data file
Set oTextStream = oFSO.OpenTextFile("wslist.txt")
'make an array from the data file
RemotePC = Split(oTextStream.ReadAll, vbNewLine)
'close the data file
oTextStream.Close
For Each strComputer In RemotePC
	Set OpSysSet = GetObject("winmgmts:{impersonationLevel=impersonate,(RemoteShutdown)}//" & strComputer).ExecQuery("select * from Win32_OperatingSystem where Primary=true")
		for each OpSys in OpSysSet
			OpSys.Reboot()
 		next
Next

Adn the standalone version of the script that will prompt for a machine name or IP address.

'Reboot Workstation Script
'By Mark MacLachlan
'Creation Date 9/18/2002
'Modification 10/7/2002 Added support for confirmation box
'Usage- Double click and enter a machine name or IP address to reboot machine


On Error Resume Next
mname = InputBox("Enter Machine Name", "Reboot Machine")
If Len(mname) = 0 Then Wscript.Quit

if Msgbox("Are you sure you want to reboot machine " & mname, vbYesNo, "Reboot Machine") = vbYes then

		Set OpSysSet = GetObject("winmgmts:{impersonationLevel=impersonate,(RemoteShutdown)}//" & mname).ExecQuery("select * from Win32_OperatingSystem where Primary=true")
		for each OpSys in OpSysSet
			OpSys.Reboot()
 		next
end if

I hope you find this post helpful.

Regards,

Mark

 

[krenkey]

thanks mark, i wil try it in my environment