ADO Export To Excel Spreadsheet 1

[PaulinKC]

I've got a quick question regarding exporting an ADO recordset to an excel spreadsheet. The following code taken from msdn.microsoft.com exports the recordset to the spreadsheet, but I have yet to see an example of how to just create a new spreadsheet and then save the spreadsheet without ever seeing excel popup. Does anyone know how to do that?

Private Sub Command1_Click()
Dim cnt As New ADODB.Connection
Dim rst As New ADODB.Recordset

Dim xlApp As Object
Dim xlWb As Object
Dim xlWs As Object


Dim recArray As Variant

Dim strDB As String
Dim fldCount As Integer
Dim recCount As Long
Dim iCol As Integer
Dim iRow As Integer

' Set the string to the path of your Northwind database
strDB = "c:\Program Files\Microsoft Office\Office\Samples\Northwind.mdb"

' Open connection to the database
cnt.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & strDB & ";"

' Open recordset based on Orders table
rst.Open "Select * From Orders", cnt

' Create an instance of Excel and add a workbook
Set xlApp = CreateObject("Excel.Application&quot
Set xlWb = xlApp.Workbooks.Add
Set xlWs = xlWb.Worksheets("Sheet1&quot

' Display Excel and give user control of Excel's lifetime
xlApp.Visible = True
xlApp.UserControl = True

' Copy field names to the first row of the worksheet
fldCount = rst.Fields.Count
For iCol = 1 To fldCount
xlWs.Cells(1, iCol).Value = rst.Fields(iCol - 1).Name
Next

' Check version of Excel
If Val(Mid(xlApp.Version, 1, InStr(1, xlApp.Version, ".&quot - 1)) > 8 Then
'EXCEL 2000 or 2002: Use CopyFromRecordset

' Copy the recordset to the worksheet, starting in cell A2
xlWs.Cells(2, 1).CopyFromRecordset rst
'Note: CopyFromRecordset will fail if the recordset
'contains an OLE object field or array data such
'as hierarchical recordsets

Else
'EXCEL 97 or earlier: Use GetRows then copy array to Excel

' Copy recordset to an array
recArray = rst.GetRows
'Note: GetRows returns a 0-based array where the first
'dimension contains fields and the second dimension
'contains records. We will transpose this array so that
'the first dimension contains records, allowing the
'data to appears properly when copied to Excel

' Determine number of records

recCount = UBound(recArray, 2) + 1 '+ 1 since 0-based array


' Check the array for contents that are not valid when
' copying the array to an Excel worksheet
For iCol = 0 To fldCount - 1
For iRow = 0 To recCount - 1
' Take care of Date fields
If IsDate(recArray(iCol, iRow)) Then
recArray(iCol, iRow) = Format(recArray(iCol, iRow))
' Take care of OLE object fields or array fields
ElseIf IsArray(recArray(iCol, iRow)) Then
recArray(iCol, iRow) = "Array Field"
End If
Next iRow 'next record
Next iCol 'next field

' Transpose and Copy the array to the worksheet,
' starting in cell A2
xlWs.Cells(2, 1).Resize(recCount, fldCount).Value = _
TransposeDim(recArray)
End If

' Auto-fit the column widths and row heights
xlApp.Selection.CurrentRegion.Columns.AutoFit
xlApp.Selection.CurrentRegion.Rows.AutoFit

' Close ADO objects
rst.Close
cnt.Close
Set rst = Nothing
Set cnt = Nothing

' Release Excel references
Set xlWs = Nothing
Set xlWb = Nothing

Set xlApp = Nothing

End Sub


Function TransposeDim(v As Variant) As Variant
' Custom Function to Transpose a 0-based array (v)

Dim X As Long, Y As Long, Xupper As Long, Yupper As Long
Dim tempArray As Variant

Xupper = UBound(v, 2)
Yupper = UBound(v, 1)

ReDim tempArray(Xupper, Yupper)
For X = 0 To Xupper
For Y = 0 To Yupper
tempArray(X, Y) = v(Y, X)
Next Y
Next X

TransposeDim = tempArray

End Function

 

[mattKnight]

altering the line

xlApp.Visible = True

to

xlApp.Visible = False

would be a start


Take Care

Matt
If at first you don't succeed, skydiving is not for you.

 

[tb]

Remember to save your work sheet if you use

>xlsApp.Visible = False (mattknight)



The pen is mightier than the sword - and quite frankly . . easier to write with

 

[PaulinKC]

>>>Remember to save your work sheet if you use

>>>>xlsApp.Visible = False (mattknight)

Ok that should work, but how do I save it? That's what I want to know as I cannot find anything relating to just saving the file to like C:\temp\temp.xls ?

 

[tb]

xlWb.SaveAs (Filename, Fileformat, Password, WritePassword, ReadOnlyRecommended,CreateBackup,AccessMode(xlExclusive/xlNoChang/xlSahred),ConflictResolution,AddToMru,TextCodePage,TextVisualLayout)

All options in brackets are optional.

Do yourself a favour start a new app and reference the Excel Object and declare
xlsApp as Excel.Application
xlsWB as Excel.Workbook
xlsSheet as Excel.Sheet

You'll have intellisense and it will be easier to understand.



The pen is mightier than the sword - and quite frankly . . easier to write with

 

[PaulinKC]

thanks for the info theBitchie!

 

[tb]

thnx 4 the star !!



The pen is mightier than the sword - and quite frankly . . easier to write with

 

[PaulinKC]

No problem... was very helpful info!